dev-util/include-what-you-use: add 0.18

Signed-off-by: Florian Schmaus <flow@gentoo.org>

1 files changed, 58 insertions, 0 deletions

diff --git a/dev-util/include-what-you-use/include-what-you-use-0.18.ebuild b/dev-util/include-what-you-use/include-what-you-use-0.18.ebuild
new file mode 100644
index 000000000000..2afa1f67ebcc
--- /dev/null
+++ b/dev-util/include-what-you-use/include-what-you-use-0.18.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit cmake llvm python-single-r1
+
+DESCRIPTION="Find unused include directives in C/C++ programs"
+HOMEPAGE="https://include-what-you-use.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+LLVM_MAX_SLOT=14
+
+RDEPEND="
+	sys-devel/clang:${LLVM_MAX_SLOT}
+	sys-devel/llvm:${LLVM_MAX_SLOT}
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+llvm_check_deps() {
+	has_version "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+	llvm_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+	python_fix_shebang .
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# Note [llvm install path]
+		# Unfortunately all binaries using clang driver
+		# have to reside at the same path depth as
+		# 'clang' binary itself. See bug #625972
+		# Thus as a hack we install it to the same directory
+		# as llvm/clang itself.
+		-DCMAKE_INSTALL_PREFIX="$(get_llvm_prefix "${LLVM_MAX_SLOT}")"
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	"${EPYTHON}" run_iwyu_tests.py
+}