dev-util/diffoscope: add 189

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 111 insertions, 0 deletions

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index f517ef74c4d9..8c407a73e06e 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -2,3 +2,4 @@ DIST diffoscope-180.tar.gz 1600542 BLAKE2B 0cc34106f039e0682b32de284b3ce1be90e86
 DIST diffoscope-186.tar.gz 2685030 BLAKE2B b9fcb05fbdd939ece3727f232777c56119aa5df837699dcdc752a816bb656aa09c4cce99e225425e09d55914523a6456587bf232877fa22924c623f854016712 SHA512 13d42ba600cc9c5e716162a73f42d8453358f689f4148b138121e1f2190b1334a66a01fd0e227bc9e7190d3229c286be91d6ccbdd21c13694fc2edab8e5019cd
 DIST diffoscope-187.tar.gz 2699208 BLAKE2B 193eb0575814df7ee1d0a0e989a936782a52d4c8dc3e56d47db7ff5d631776559a604755e1d1be6687c1168ef7bb9d899f3b5ea8cab9506ef5b2da195485d7e0 SHA512 b3ba6743c9c4e0460f56a0830801f72e00bf7500c54dd9392e6e1de470a3b7348d900a8b9012f17b509abbc59575c7b9ee8e1048b3b23e5813a5ddabeadb1be4
 DIST diffoscope-188.tar.gz 2703049 BLAKE2B 2d517a6067a70221a34545456e23eefb42b5dbae1daa3459366ad429446844d64714ab5d229cd909de533b8994e870d16314282454ce2ebbf3408685e6b94f5f SHA512 b2c17bd577d5450439d2871f027f675f4e5bbfdc26e0f18bbe3579f214b023e1610a2095aec4b9d91c52e4a4c3e5fb226209e8f1c643b1c82ec190124d5d47d5
+DIST diffoscope-189.tar.gz 2703482 BLAKE2B 9c3a86b71d02c456b72955ddc2c9df580c60c898b00cdebaeea369065536b531fd93cbc12f25d9d94ca6bf1cb11bf90f28e6c77f3573a623b35174e59466778d SHA512 4c9a8c909cc18fa524be3979e211420b1240b7336a5895ec7e8682786e01952c6ae2ed494796aa08cdff2b21d13a55c4f47cb8e947743407e38790e8b40fb04c
diff --git a/dev-util/diffoscope/diffoscope-189.ebuild b/dev-util/diffoscope/diffoscope-189.ebuild
new file mode 100644
index 000000000000..bd59e85cceb9
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-189.ebuild
@@ -0,0 +1,110 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10} )
+PYTHON_REQ_USE="ncurses"
+
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+
+RESTRICT="!test? ( test )"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="test? (
+		app-text/docx2txt
+		media-libs/libcaca
+		virtual/imagemagick-tools[jpeg]
+	)"
+RDEPEND="dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-arch/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( sys-devel/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/PyPDF2[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( net-misc/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+# Presence if filemagic's magic.py breaks imports
+# of dev-python/python-magic: https://bugs.gentoo.org/716482
+RDEPEND+=" !dev-python/filemagic"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local exclude=(
+		# test seems to use different tarball
+		tests/test_presenters.py::test_text_proper_indentation
+
+		# needs triage
+		tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+
+		# needs triage
+		tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+
+		# img2txt based failures, bug #797688
+		tests/comparators/test_ico_image.py::test_diff
+		tests/comparators/test_ico_image.py::test_diff_meta
+		tests/comparators/test_ico_image.py::test_diff_meta2
+		tests/comparators/test_ico_image.py::test_has_visuals
+		tests/comparators/test_jpeg_image.py::test_diff
+		tests/comparators/test_jpeg_image.py::test_compare_non_existing
+		tests/comparators/test_jpeg_image.py::test_diff_meta
+		tests/comparators/test_jpeg_image.py::test_has_visuals
+
+		# docx2txt based falures, bug #797688
+		tests/comparators/test_docx.py::test_diff
+	)
+	epytest ${exclude[@]/#/--deselect }
+}