games-action/minetest: Version bump to 5.3.0

Closes: https://bugs.gentoo.org/731984
Signed-off-by: William Breathitt Gray <vilhelm.gray@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/16653
Signed-off-by: James Le Cuirot <chewi@gentoo.org>

2 files changed, 141 insertions, 0 deletions

diff --git a/games-action/minetest/Manifest b/games-action/minetest/Manifest
index ea2ab27923e2..8d2b900d5b71 100644
--- a/games-action/minetest/Manifest
+++ b/games-action/minetest/Manifest
@@ -1 +1,2 @@
 DIST minetest-5.2.0.tar.gz 10361815 BLAKE2B 244cacc92f08f571f45bedef9a8f2154a8105fc83c1396d626e78dcb0d4050c3ba9610ccf2ec2864a5d4b73d9d31aac0dc162fdcc277ef35cc1ead53158cc51f SHA512 47e3cdf488d50ea61659ac3b72960c9971270d1a793e0d79dcb649c89f7a6e65a16c21e1b903d08c916a2ebcbd3fd2164ec67173a3d4f2a2e9bb3a6351b48851
+DIST minetest-5.3.0.tar.gz 10828893 BLAKE2B 0847c040d2874962be79af6fce89b19354f6763cb37dd61d7e5e91bcacb9a76a115e295976056ae761db257612277ceef0d7e8bfc55790b1bc59a9c4961af41b SHA512 7bb34a80107861539a9ac2417812625ef11d145bf9401afdb8e0a1b9f619adcce24e2becf5bf361b805f4610097cf9d44c76d497ab08d489a43655852ce44777
diff --git a/games-action/minetest/minetest-5.3.0.ebuild b/games-action/minetest/minetest-5.3.0.ebuild
new file mode 100644
index 000000000000..94e307d76447
--- /dev/null
+++ b/games-action/minetest/minetest-5.3.0.ebuild
@@ -0,0 +1,140 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+DESCRIPTION="A free open-source voxel game engine with easy modding and game creation"
+HOMEPAGE="https://www.minetest.net"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0 OFL-1.1 Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+client +curl doc +leveldb ncurses nls postgres redis +server +sound spatial test +truetype"
+REQUIRED_USE="|| ( client server )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-db/sqlite:3
+	dev-lang/luajit:2
+	dev-libs/gmp:0=
+	dev-libs/jsoncpp:=
+	sys-libs/zlib
+	client? (
+		app-arch/bzip2
+		dev-games/irrlicht
+		media-libs/libpng:0=
+		virtual/jpeg:0
+		virtual/opengl
+		x11-libs/libX11
+		x11-libs/libXxf86vm
+		sound? (
+			media-libs/libogg
+			media-libs/libvorbis
+			media-libs/openal
+		)
+		truetype? ( media-libs/freetype:2 )
+	)
+	curl? ( net-misc/curl )
+	leveldb? ( dev-libs/leveldb:= )
+	ncurses? ( sys-libs/ncurses:0= )
+	nls? ( virtual/libintl )
+	postgres? ( >=dev-db/postgresql-9.5:= )
+	redis? ( dev-libs/hiredis:= )
+	server? (
+		acct-group/minetest
+		acct-user/minetest
+		dev-games/irrlicht-headers
+	)
+	spatial? ( sci-libs/libspatialindex:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? (
+		app-doc/doxygen
+		media-gfx/graphviz
+	)
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	cmake_src_prepare
+	# set paths
+	sed \
+		-e "s#@BINDIR@#${EPREFIX}/usr/bin#g" \
+		-e "s#@GROUP@#${PN}#g" \
+		"${FILESDIR}"/minetestserver.confd > "${T}"/minetestserver.confd || die
+
+	# remove bundled libraries
+	rm -rf lib || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_CLIENT=$(usex client)
+		-DBUILD_SERVER=$(usex server)
+		-DBUILD_UNITTESTS=$(usex test)
+		-DCUSTOM_BINDIR="${EPREFIX}/usr/bin"
+		-DCUSTOM_DOCDIR="${EPREFIX}/usr/share/doc/${PF}"
+		-DCUSTOM_EXAMPLE_CONF_DIR="${EPREFIX}/usr/share/doc/${PF}"
+		-DCUSTOM_LOCALEDIR="${EPREFIX}/usr/share/${PN}/locale"
+		-DCUSTOM_SHAREDIR="${EPREFIX}/usr/share/${PN}"
+		-DENABLE_CURL=$(usex curl)
+		-DENABLE_CURSES=$(usex ncurses)
+		-DENABLE_FREETYPE=$(usex truetype)
+		-DENABLE_GETTEXT=$(usex nls)
+		-DENABLE_GLES=0
+		-DENABLE_LEVELDB=$(usex leveldb)
+		-DENABLE_LUAJIT=1
+		-DENABLE_POSTGRESQL=$(usex postgres)
+		-DENABLE_REDIS=$(usex redis)
+		-DENABLE_SPATIAL=$(usex spatial)
+		-DENABLE_SOUND=$(usex sound)
+		-DENABLE_SYSTEM_GMP=1
+		-DENABLE_SYSTEM_JSONCPP=1
+		-DRUN_IN_PLACE=0
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	if use doc ; then
+		cmake_src_compile doc
+		HTML_DOCS=( "${BUILD_DIR}"/doc/html/. )
+	fi
+}
+
+src_install() {
+	cmake_src_install
+
+	if use server ; then
+		keepdir /var/log/minetest
+		fowners minetest:minetest /var/log/minetest
+
+		newconfd "${T}"/minetestserver.confd minetest-server
+		newinitd "${FILESDIR}"/minetestserver.initd minetest-server
+
+		insinto /etc/logrotate.d
+		newins "${FILESDIR}"/minetestserver.logrotate minetest-server
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if use server ; then
+		elog
+		elog "Configure your server via /etc/conf.d/minetest-server"
+		elog
+	fi
+
+	elog
+	elog "The version 5.x series is not compatible to the version 0.4 series."
+	elog "This applies to clients and servers, other content such as mods,"
+	elog "texture packs and worlds is unaffected and backwards-compatible"
+	elog "as usual."
+	elog
+}