games-action/minetest: Version bump to 5.1.1

Closes: https://bugs.gentoo.org/706372
Closes: https://bugs.gentoo.org/705696
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: William Breathitt Gray <vilhelm.gray@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/14370
Signed-off-by: James Le Cuirot <chewi@gentoo.org>

2 files changed, 140 insertions, 0 deletions

diff --git a/games-action/minetest/Manifest b/games-action/minetest/Manifest
index 11699c9e760a..32bddbc98b7e 100644
--- a/games-action/minetest/Manifest
+++ b/games-action/minetest/Manifest
@@ -1 +1,2 @@
 DIST minetest-5.1.0.tar.gz 8939376 BLAKE2B 5c56bd74a573632636937c5e5a45eb864ec627962b73573a763be7326c2a3fa95ad87683d655725b29d29d91270812beef33c21b3eb100627f21befeb2dbfac5 SHA512 f2cad4720c1003536cc3c619c18234a95cae1dee8fb54b46a2ef5fd24108a4c945efcb0a461926ef3ede7b8bec41ed6620806212fe11f4142bbf31fe4f0f659e
+DIST minetest-5.1.1.tar.gz 9002025 BLAKE2B 8258850a0f45125a09e0a4cf5eda7a8860be4f0a5e564767952e27fc8509593bf0615c1457a0ee168f6eeedcf1065e288b787d74e1d0a2180870bc1bae818bfc SHA512 4a36a86a3e5f8f5246ff3410e9ab182631f38292bea077e7dbc25fdc1520e5a479ffbd5ec447000fb4999ab252a59bf976299e6fecda1f8cd47f40549885766b
diff --git a/games-action/minetest/minetest-5.1.1.ebuild b/games-action/minetest/minetest-5.1.1.ebuild
new file mode 100644
index 000000000000..66f7329bb98e
--- /dev/null
+++ b/games-action/minetest/minetest-5.1.1.ebuild
@@ -0,0 +1,139 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+DESCRIPTION="A free open-source voxel game engine with easy modding and game creation"
+HOMEPAGE="https://www.minetest.net"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0 OFL-1.1 Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+client +curl doc +leveldb ncurses nls postgres redis +server +sound spatial +truetype"
+REQUIRED_USE="|| ( client server )"
+
+RDEPEND="
+	dev-db/sqlite:3
+	dev-lang/luajit:2
+	dev-libs/gmp:0=
+	dev-libs/jsoncpp:=
+	sys-libs/zlib
+	client? (
+		app-arch/bzip2
+		dev-games/irrlicht
+		media-libs/libpng:0=
+		virtual/jpeg:0
+		virtual/opengl
+		x11-libs/libX11
+		x11-libs/libXxf86vm
+		sound? (
+			media-libs/libogg
+			media-libs/libvorbis
+			media-libs/openal
+		)
+		truetype? ( media-libs/freetype:2 )
+	)
+	curl? ( net-misc/curl )
+	leveldb? ( dev-libs/leveldb:= )
+	ncurses? ( sys-libs/ncurses:0= )
+	nls? ( virtual/libintl )
+	postgres? ( >=dev-db/postgresql-9.5:= )
+	redis? ( dev-libs/hiredis:= )
+	server? (
+		acct-group/minetest
+		acct-user/minetest
+		dev-games/irrlicht-headers
+	)
+	spatial? ( sci-libs/libspatialindex:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? (
+		app-doc/doxygen
+		media-gfx/graphviz
+	)
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	cmake_src_prepare
+	# set paths
+	sed \
+		-e "s#@BINDIR@#${EPREFIX}/usr/bin#g" \
+		-e "s#@GROUP@#${PN}#g" \
+		"${FILESDIR}"/minetestserver.confd > "${T}"/minetestserver.confd || die
+
+	# remove bundled libraries
+	rm -rf lib || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_CLIENT=$(usex client)
+		-DBUILD_SERVER=$(usex server)
+		-DCUSTOM_BINDIR="${EPREFIX}/usr/bin"
+		-DCUSTOM_DOCDIR="${EPREFIX}/usr/share/doc/${PF}"
+		-DCUSTOM_EXAMPLE_CONF_DIR="${EPREFIX}/usr/share/doc/${PF}"
+		-DCUSTOM_LOCALEDIR="${EPREFIX}/usr/share/${PN}/locale"
+		-DCUSTOM_SHAREDIR="${EPREFIX}/usr/share/${PN}"
+		-DENABLE_CURL=$(usex curl)
+		-DENABLE_CURSES=$(usex ncurses)
+		-DENABLE_FREETYPE=$(usex truetype)
+		-DENABLE_GETTEXT=$(usex nls)
+		-DENABLE_GLES=0
+		-DENABLE_LEVELDB=$(usex leveldb)
+		-DENABLE_LUAJIT=1
+		-DENABLE_POSTGRESQL=$(usex postgres)
+		-DENABLE_REDIS=$(usex redis)
+		-DENABLE_SPATIAL=$(usex spatial)
+		-DENABLE_SOUND=$(usex sound)
+		-DENABLE_SYSTEM_GMP=1
+		-DENABLE_SYSTEM_JSONCPP=1
+		-DRUN_IN_PLACE=0
+	)
+
+	use server && mycmakeargs+=(
+		-DIRRLICHT_INCLUDE_DIR="${EPREFIX}/usr/include/irrlicht"
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	if use doc ; then
+		cmake_src_compile doc
+		HTML_DOCS=( "${BUILD_DIR}"/doc/html/. )
+	fi
+}
+
+src_install() {
+	cmake_src_install
+
+	if use server ; then
+		keepdir /var/log/minetest
+		fowners minetest:minetest /var/log/minetest
+
+		newconfd "${T}"/minetestserver.confd minetest-server
+		newinitd "${FILESDIR}"/minetestserver.initd minetest-server
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if use server ; then
+		elog
+		elog "Configure your server via /etc/conf.d/minetest-server"
+		elog
+	fi
+
+	elog
+	elog "The version 5.x series is not compatible to the version 0.4 series."
+	elog "This applies to clients and servers, other content such as mods,"
+	elog "texture packs and worlds is unaffected and backwards-compatible"
+	elog "as usual."
+	elog
+}