games-board/atakks: add missing EPREFIX, minor fixups

- remove homepage, no upstream
- license to GPL-2+ ("or later" is stated in French)
- add missing einstalldocs
- remove non-XDG compliant .bmp icon (typically not displayed)
- revbump given EPREFIX affects runtime and added minor [video] to SDL

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/games-board/atakks/atakks-1.0-r2.ebuild b/games-board/atakks/atakks-1.0-r2.ebuild
new file mode 100644
index 000000000000..8da2077bfe0e
--- /dev/null
+++ b/games-board/atakks/atakks-1.0-r2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop toolchain-funcs
+
+DESCRIPTION="Clone of Ataxx"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="mirror://gentoo/${P}.tar.gz"
+S="${WORKDIR}/${PN}_${PV}"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="media-libs/libsdl[video]"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PV}-warnings.patch
+	"${FILESDIR}"/${P}-as-needed.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i "/LoadBMP/s|\"|\"${EPREFIX}/usr/share/${PN}/|" main.c || die
+}
+
+src_compile() {
+	tc-export CC
+
+	emake E_CFLAGS="${CFLAGS}"
+}
+
+src_install() {
+	dobin ${PN}
+
+	insinto /usr/share/${PN}
+	doins *.bmp
+
+	make_desktop_entry ${PN} Atakks applications-games
+
+	einstalldocs
+}