games-board/gnubg: add 1.07.001

Add myself to maintainers for potential follow-up bugs

Closes: https://bugs.gentoo.org/761706
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

3 files changed, 107 insertions, 0 deletions

diff --git a/games-board/gnubg/Manifest b/games-board/gnubg/Manifest
index 20598b9b688e..3ca4eb64f034 100644
--- a/games-board/gnubg/Manifest
+++ b/games-board/gnubg/Manifest
@@ -1 +1,2 @@
 DIST gnubg-release-1.06.002-sources.tar.gz 13163681 BLAKE2B 1b631af8b268c722624012f86318844376bb21158f231d807cbfbb101ecef03ed90f7f253121844dd4221dc8026af5619fe9f62aff64e20d6c2b84450f9705d0 SHA512 77594209032a0d81deb802da249d7f40812127dd1e080413eda75015f324fec9592b1b51772403f501b21e39d3dd371931d82b43c24f614a7d16c5234d271948
+DIST gnubg-release-1.07.001-sources.tar.gz 13729158 BLAKE2B 3c5a0ffd38d2f1a16b3bf188a6ed6ba38e9527d681ad510b2e318b6f5da7d5fb1e0728f4f562fe4d770710489e7eae1396318e26717a51434fa8b4c3258570f9 SHA512 0643af4c3c6e32774e3572462755e7eed094fcc9621dc8262ce0f794657f00a3dbc22d0f916580982a6dacc08488544cd5fec5bf7e2c60ca50f83e2a60804e08
diff --git a/games-board/gnubg/gnubg-1.07.001.ebuild b/games-board/gnubg/gnubg-1.07.001.ebuild
new file mode 100644
index 000000000000..13f24f2f9417
--- /dev/null
+++ b/games-board/gnubg/gnubg-1.07.001.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit autotools desktop python-single-r1 xdg
+
+DESCRIPTION="GNU BackGammon"
+HOMEPAGE="https://www.gnu.org/software/gnubg/"
+SRC_URI="mirror://gnu/${PN}/${PN}-release-${PV}-sources.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+IUSE="
+	cpu_flags_x86_avx cpu_flags_x86_sse cpu_flags_x86_sse2
+	gui opengl python sqlite"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
+	opengl? ( gui )"
+
+RDEPEND="
+	dev-libs/cglm
+	dev-libs/glib:2
+	dev-libs/gmp:=
+	media-fonts/dejavu
+	media-libs/freetype:2
+	media-libs/libpng:=
+	net-misc/curl
+	sys-libs/readline:=
+	virtual/libintl
+	x11-libs/cairo[svg(+)]
+	x11-libs/pango
+	gui? (
+		media-libs/libcanberra[gtk3]
+		x11-libs/gdk-pixbuf:2
+		x11-libs/gtk+:3
+	)
+	opengl? ( media-libs/libepoxy )
+	python? ( ${PYTHON_DEPS} )
+	sqlite? ( dev-db/sqlite:3 )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/autoconf-archive
+	sys-devel/gettext
+	virtual/pkgconfig
+	python? ( ${PYTHON_DEPS} )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	#This was provided by gtkglext before
+	sed -i "s/\$(GTKGLEXT_LIBS)/-lGL/" Makefile.am || die
+
+	sed -i "s|/tmp|${T}|" credits.sh || die #298275
+	sed -i 's/fonts //' Makefile.am || die #335774
+	sed -i 's/gzip/true/' doc/Makefile.am || die
+
+	# use system's copy so py3.10 distutils warning doesn't trigger a fatal error
+	rm m4/ax_python_devel.m4 || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local simd=no
+	use cpu_flags_x86_sse  && simd=sse
+	use cpu_flags_x86_sse2 && simd=sse2
+	use cpu_flags_x86_avx  && simd=avx
+
+	local econfargs=(
+		$(use_with gui gtk)
+		$(use_with gui gtk3)
+		$(use_with opengl board3d)
+		$(use_with python)
+		$(use_with sqlite)
+		--disable-cputest
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}/html
+		--enable-simd=${simd}
+	)
+
+	econf "${econfargs[@]}"
+}
+
+src_install() {
+	default
+
+	mv "${ED}"/usr/share/doc/${PF}{/html/*.pdf,} || die
+
+	insinto /usr/share/${PN}
+	doins ${PN}.weights *.bd
+
+	dosym ../../fonts/dejavu/DejaVuSans.ttf /usr/share/${PN}/fonts/Vera.ttf
+	dosym ../../fonts/dejavu/DejaVuSans-Bold.ttf /usr/share/${PN}/fonts/VeraBd.ttf
+	dosym ../../fonts/dejavu/DejaVuSerif-Bold.ttf /usr/share/${PN}/fonts/VeraSeBd.ttf
+
+	use gui && make_desktop_entry "gnubg -w" "GNU Backgammon"
+}
diff --git a/games-board/gnubg/metadata.xml b/games-board/gnubg/metadata.xml
index 57428f3202d7..d922047d09f8 100644
--- a/games-board/gnubg/metadata.xml
+++ b/games-board/gnubg/metadata.xml
@@ -5,6 +5,10 @@
     <email>games@gentoo.org</email>
     <name>Gentoo Games Project</name>
   </maintainer>
+  <maintainer type="person">
+    <email>voyageur@gentoo.org</email>
+    <name>Bernard Cafarelli</name>
+  </maintainer>
   <upstream>
     <remote-id type="savannah">gnubg</remote-id>
   </upstream>