proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 70 insertions, 0 deletions

diff --git a/games-emulation/yabause/yabause-0.9.14.ebuild b/games-emulation/yabause/yabause-0.9.14.ebuild
new file mode 100644
index 000000000000..93e58c9afd34
--- /dev/null
+++ b/games-emulation/yabause/yabause-0.9.14.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils cmake-utils games
+
+DESCRIPTION="A Sega Saturn emulator"
+HOMEPAGE="http://yabause.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="openal opengl pic qt5 sdl"
+
+# x11-libs/libXrandr is an automagic dep
+# qt5 over qt4 and libsdl2 over libsdl is
+# also done automatically.  Send patches
+# upstream to make the choices explicit.
+RDEPEND="
+	x11-libs/libXrandr
+	openal? ( media-libs/openal )
+	opengl? (
+		media-libs/freeglut
+		virtual/glu
+		virtual/opengl
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtwidgets:5[opengl?]
+		opengl? ( dev-qt/qtopengl:5 )
+	)
+	!qt5? (
+		dev-libs/glib:2
+		x11-libs/gtk+:2
+		x11-libs/gtkglext
+	)
+	sdl? ( media-libs/libsdl2[opengl?,video] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-RWX.patch \
+		"${FILESDIR}"/${P}-cmake.patch
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBINDIR="${GAMES_BINDIR}"
+		-DTRANSDIR="${GAMES_DATADIR}"/${PN}/yts
+		-DYAB_OPTIMIZATION=""
+		$(cmake-utils_use sdl YAB_WANT_SDL)
+		$(cmake-utils_use openal YAB_WANT_OPENAL)
+		$(cmake-utils_use opengl YAB_WANT_OPENGL)
+		$(cmake-utils_use !pic SH2_DYNAREC)
+		-DYAB_PORTS=$(usex qt5 "qt" "gtk")
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+	dodoc AUTHORS ChangeLog GOALS README README.LIN
+	prepgamesdirs
+}