games-rpg/baldurs-gate-ee: fix openssl-compat dep

Closes: https://bugs.gentoo.org/909533
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/games-rpg/baldurs-gate-ee/baldurs-gate-ee-2.6.6.0.47291-r1.ebuild b/games-rpg/baldurs-gate-ee/baldurs-gate-ee-2.6.6.0.47291-r1.ebuild
new file mode 100644
index 000000000000..bd3bbb79ce38
--- /dev/null
+++ b/games-rpg/baldurs-gate-ee/baldurs-gate-ee-2.6.6.0.47291-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop unpacker wrapper
+
+DESCRIPTION="Baldur's Gate: Enhanced Edition"
+HOMEPAGE="https://baldursgate.beamdog.com/"
+SRC_URI="baldur_s_gate_enhanced_edition_${PV//./_}.sh"
+
+LICENSE="GOG-EULA"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+RESTRICT="bindist fetch"
+
+RDEPEND="dev-libs/expat
+	dev-libs/openssl-compat:1.0.0
+	media-libs/openal
+	virtual/opengl
+	x11-libs/libX11"
+BDEPEND="app-arch/unzip"
+
+QA_PRESTRIPPED="opt/${PN}/BaldursGate"
+
+S="${WORKDIR}/data/noarch"
+
+pkg_nofetch() {
+	einfo "Please buy and download \"${SRC_URI}\" from"
+	einfo "https://www.gog.com/game/baldurs_gate_enhanced_edition"
+	einfo "and place it in your DISTDIR directory."
+}
+
+src_unpack() {
+	unpack_zip ${A}
+}
+
+src_install() {
+	local dir="/opt/${PN}"
+
+	dodoc -r "game/Manuals/."
+	rm -r "game/Manuals" || die "rm failed"
+
+	insinto "${dir}"
+	doins -r "game/."
+	fperms +x "${dir}/BaldursGate"
+
+	make_wrapper ${PN} "./BaldursGate" "${dir}"
+
+	newicon "support/icon.png" "${PN}.png"
+	make_desktop_entry "${PN}" "Baldur's Gate: Enhanced Edition" "${PN}"
+}