proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 81 insertions, 0 deletions

diff --git a/games-strategy/netherearth/netherearth-0.52.ebuild b/games-strategy/netherearth/netherearth-0.52.ebuild
new file mode 100644
index 000000000000..ef93d435739b
--- /dev/null
+++ b/games-strategy/netherearth/netherearth-0.52.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils games
+
+MY_PV="${PV/./}"
+DESCRIPTION="A remake of the SPECTRUM game Nether Earth"
+HOMEPAGE="http://www.braingames.getput.com/nether/"
+SRC_URI="http://www.braingames.getput.com/nether/sources.zip
+	http://www.braingames.getput.com/nether/${PN}${MY_PV}.zip"
+
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="x86"
+IUSE=""
+RESTRICT="mirror bindist"
+
+RDEPEND=">=media-libs/libsdl-1.2.6-r3
+	>=media-libs/sdl-mixer-1.2.5-r1
+	media-libs/freeglut"
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+S=${WORKDIR}/sources
+
+data=../nether\ earth\ v${PV}
+
+src_unpack() {
+	unzip -LL "${DISTDIR}/${PN}${MY_PV}.zip" >/dev/null || die
+	unzip -LL "${DISTDIR}/sources.zip" >/dev/null || die
+}
+
+src_prepare() {
+	DATA_DIR=${GAMES_DATADIR}/${PN}
+
+	cp "${FILESDIR}/Makefile" . || die
+
+	# Fix compilation errors/warnings
+	epatch "${FILESDIR}"/${P}-linux.patch
+
+	epatch "${FILESDIR}"/${P}-freeglut.patch \
+		"${FILESDIR}"/${P}-glibc-212.patch \
+		"${FILESDIR}"/${P}-ldflags.patch
+
+	# Modify dirs and some fopen() permissions
+	epatch "${FILESDIR}/${P}-gentoo-paths.patch"
+	sed -i \
+		-e "s:models:${DATA_DIR}/models:" \
+		-e "s:textures:${DATA_DIR}/textures:" \
+		-e "s:maps/\*:${DATA_DIR}/maps/\*:" \
+		-e "s:\./maps:${DATA_DIR}/maps:" \
+		mainmenu.cpp || die
+	sed -i \
+		-e "s:models:${DATA_DIR}/models:g" \
+		-e "s:textures:${DATA_DIR}/textures:" \
+		-e "s:sound/:${DATA_DIR}/sound/:" \
+		nether.cpp || die
+	sed -i -e "s:maps:${DATA_DIR}/maps:" \
+		main.cpp || die
+	sed -i -e "s:textures/:${DATA_DIR}/textures/:" \
+		myglutaux.cpp || die
+
+	cd "${data}"
+	rm textures/thumbs.db
+}
+
+src_install() {
+	dogamesbin nether_earth
+
+	cd "${data}"
+
+	# Install all game data
+	insinto "${DATA_DIR}"
+	doins -r maps models sound textures
+
+	dodoc readme.txt
+
+	prepgamesdirs
+}