kde-apps: Add KDE Release Service 19.12.0

Package-Manager: Portage-2.3.79, Repoman-2.3.16
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 98 insertions, 0 deletions

diff --git a/kde-apps/dolphin/Manifest b/kde-apps/dolphin/Manifest
index 6feb54ccf478..50cf7f50a48d 100644
--- a/kde-apps/dolphin/Manifest
+++ b/kde-apps/dolphin/Manifest
@@ -1 +1,2 @@
 DIST dolphin-19.08.3.tar.xz 5276344 BLAKE2B f894ab567be12bd3c6194c84897c13201a286064f9b1e10690b88433ae712d4d14870783d729d1d61fde89700709ae75262111684ef592e66c1c3c66bb606e9d SHA512 4390f97398b437b24f0139982e068e32a042a0740790b7dbf19747cd77b41c70dd04f0c6ba3120775f8ce48f43bdd3d2cff4590ba5556773950dd73dd9f7aad0
+DIST dolphin-19.12.0.tar.xz 4779296 BLAKE2B 9ca84a44fbcc10c4d9d3cad297f06ea4aa17942e795292a746873beec4ff69fdbd8ba0a0e3908929b60ef7f0f8e2013ca320e328222aee04052ef293c8522ad4 SHA512 e9f47d8ed9e5b3def97182d9d1600730aa41e69d32aaf49b705fe2542eeda93ec719624e735e5f7d36a1dbf64c58e2a7f177e3ac4daf303ad5a2ba519d03923e
diff --git a/kde-apps/dolphin/dolphin-19.12.0.ebuild b/kde-apps/dolphin/dolphin-19.12.0.ebuild
new file mode 100644
index 000000000000..fcaf127a47df
--- /dev/null
+++ b/kde-apps/dolphin/dolphin-19.12.0.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.63.0
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Plasma filemanager focusing on usability"
+HOMEPAGE="https://kde.org/applications/system/org.kde.dolphin
+https://userbase.kde.org/Dolphin"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="activities semantic-desktop"
+
+DEPEND="
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kinit-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	media-libs/phonon[qt5(+)]
+	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
+	semantic-desktop? (
+		>=kde-frameworks/baloo-${KFMIN}:5
+		>=kde-frameworks/kfilemetadata-${KFMIN}:5
+		>=kde-apps/baloo-widgets-${PVCUT}:5
+	)
+"
+RDEPEND="${DEPEND}
+	>=kde-apps/kio-extras-${PVCUT}:5
+"
+
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package activities KF5Activities)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+		$(cmake_use_find_package semantic-desktop KF5BalooWidgets)
+		$(cmake_use_find_package semantic-desktop KF5FileMetaData)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		has_version "kde-apps/ark:${SLOT}" || \
+			elog "For compress/extract and other actions install kde-apps/ark:${SLOT}"
+
+		has_version "kde-apps/kleopatra:${SLOT}" || \
+			elog "For crypto actions install kde-apps/kleopatra:${SLOT}"
+
+		has_version "kde-apps/ffmpegthumbs:${SLOT}" || \
+			elog "For video file thumbnails install kde-apps/ffmpegthumbs:${SLOT}"
+
+		has_version "kde-apps/thumbnailers:${SLOT}" || \
+			elog "For graphics file thumbnails install kde-apps/thumbnailers:${SLOT}"
+
+		has_version "kde-frameworks/purpose:${SLOT}" || \
+			elog "For 'Share' context menu actions install kde-frameworks/purpose:${SLOT}"
+	fi
+}