kde-apps/spectacle: 23.08.4 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 71 insertions, 0 deletions

diff --git a/kde-apps/spectacle/spectacle-23.08.4.ebuild b/kde-apps/spectacle/spectacle-23.08.4.ebuild
new file mode 100644
index 000000000000..c3c0454bdafb
--- /dev/null
+++ b/kde-apps/spectacle/spectacle-23.08.4.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="Screenshot capture utility"
+HOMEPAGE="https://apps.kde.org/spectacle/"
+
+LICENSE="LGPL-2+ handbook? ( FDL-1.3 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="share"
+
+COMMON_DEPEND="
+	dev-libs/wayland
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtwayland-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5[X]
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	kde-plasma/kpipewire:5
+	x11-libs/libxcb
+	x11-libs/xcb-util
+	x11-libs/xcb-util-cursor
+	x11-libs/xcb-util-image
+	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/plasma-wayland-protocols-1.9
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qdbus-${QTMIN}:*
+	>=dev-qt/qtmultimedia-${QTMIN}:5[qml]
+	>=dev-qt/qtsvg-${QTMIN}:5
+"
+BDEPEND="
+	>=dev-qt/qtwaylandscanner-${QTMIN}:5
+	dev-util/wayland-scanner
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package share KF5Purpose)
+	)
+	ecm_src_configure
+}