kde-frameworks/breeze-icons: 5.88.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 57 insertions, 0 deletions

diff --git a/kde-frameworks/breeze-icons/Manifest b/kde-frameworks/breeze-icons/Manifest
index 5b719edeb1e0..3bfdb1be9fa9 100644
--- a/kde-frameworks/breeze-icons/Manifest
+++ b/kde-frameworks/breeze-icons/Manifest
@@ -1,2 +1,3 @@
 DIST breeze-icons-5.85.0.tar.xz 2051056 BLAKE2B 443edc464db1248ffef50e64fe8d680e9e854ad6f389861cff242c1a174cd05ac7c77cf172ac96510fa55869d8d9657eb6a99db730b86cf7de1892dabae2f23d SHA512 78be4cdf9701d92a5e8f405bceb64334c84008cb63c08af861e7d7424e08970d07f9f8320df2e66ae3468860424792c55b26299c14cb4cf347cfd65f513ab363
 DIST breeze-icons-5.87.0.tar.xz 2107940 BLAKE2B a7fea9183e0689f3b4d533f755cd7fe7d15addf5be15d5a8c57a31f5991d0955c1f01b39d916940a23ca0f4f486b3f360ce2bff7a88c350b1ec194aa57090299 SHA512 cfd7bf1724b0fa7d68cf76b4b46e007148dfb8c2f03f9419606a543e2b21345f7ca36339f134c415342f284115d0dc7303ea5064b0ce2863b9acabe630ce6938
+DIST breeze-icons-5.88.0.tar.xz 2128308 BLAKE2B e96b04d524d99227ee09935c63ed8362b0a75a88e89835afc8537d03e360c202957392eee329397c0c502a47140d975ac2bde79738b911fd0600c6d2a3a079ab SHA512 e66ee04a2e073fe954e97dfd377581715313a041d62740eda7c4b599fd6785ca241f58508afafcb2fb3a8803df72f5e451a213dff7329f6beca87197e8e1f00d
diff --git a/kde-frameworks/breeze-icons/breeze-icons-5.88.0.ebuild b/kde-frameworks/breeze-icons/breeze-icons-5.88.0.ebuild
new file mode 100644
index 000000000000..ef153169884c
--- /dev/null
+++ b/kde-frameworks/breeze-icons/breeze-icons-5.88.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PVCUT=$(ver_cut 1-2)
+PYTHON_COMPAT=( python3_{8..10} )
+inherit cmake kde.org python-any-r1 xdg-utils
+
+DESCRIPTION="Breeze SVG icon theme"
+
+LICENSE="LGPL-3"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-qt/qttest:5 )"
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/lxml[${PYTHON_USEDEP}]')
+	dev-qt/qtcore:5
+	>=kde-frameworks/extra-cmake-modules-${PVCUT}:5
+	test? ( app-misc/fdupes )
+"
+
+python_check_deps() {
+	has_version "dev-python/lxml[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	cmake_src_prepare
+	use test || cmake_comment_add_subdirectory autotests
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython_EXECUTABLE="${PYTHON}"
+		-DBINARY_ICONS_RESOURCE=OFF
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	# bug 770988
+	find "${ED}"/usr/share/icons/ -type d -empty -delete || die
+	find "${ED}"/usr/share/icons/ -xtype l -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}