mail-filter/rspamd: version bump to 1.7.5

	Modified ebuild to handle life ebuild and stable release

3 files changed, 117 insertions, 12 deletions

diff --git a/mail-filter/rspamd/Manifest b/mail-filter/rspamd/Manifest
index 8b5ef369325c..382f8c5fe76e 100644
--- a/mail-filter/rspamd/Manifest
+++ b/mail-filter/rspamd/Manifest
@@ -2,3 +2,4 @@ DIST rspamd-1.6.5.tar.gz 2484271 BLAKE2B 880e862eecd4a082b87bee2ba8c7b17a475efbf
 DIST rspamd-1.6.6.tar.gz 2487482 BLAKE2B f18640f64a8c0bcf6077267a1715f0bb096ab18484c24de56a012c42666cdc9f8671237c5336dce7cd47f44f9aba7905ce3723232d53a5b8ddfe143df682bd9b SHA512 14c7144017df69600dbd09541d16dae19d87105b09f95811fc09624b60e89ca68200654e88dea242508afd3c4963ea7cac086abddec8ca1a3d8fc73d7c27e899
 DIST rspamd-1.7.1.tar.gz 4453460 BLAKE2B 28070804a6daf7f6354203038fbd974176a1ed5135b51a5ef7f089e63ffac3b3bbdca1961154b846f5b7d054071925722b311b46a3be6d09ff3d853232cbbd5f SHA512 3de4e07fa9cc72e306936a201f6bc019b5bf6f3ade003bf9217dc8a7decf027b986d80e1c0d2f09460af6f1d59aa520fee68287ad6ccee1cec94698054bc2fbb
 DIST rspamd-1.7.2.tar.gz 4460606 BLAKE2B 2c4389fd5350d67d21745288f74c4e1276772c47bbb0c74364227d0c04e4102c2ce00cd8242a639825e8c9971e87822af7a38a0a8561ba979e3f3b396d120414 SHA512 45ab95c7488e58da9e8803daefda5a0f8920cc4d4c4508a0347ed07d201124d07b10e93010b2be5fab3ecd0ac2be962bcebbb41f434a449fdbc31ded744878cf
+DIST rspamd-1.7.5.tar.gz 4494681 BLAKE2B 709b589157cb61568ebe78af64bb2363cb7342736e29971f30de1e1a1e9e667402006cb3a34e1d240a32560608ab9ab86838a288707b5043c89c3d9127880f60 SHA512 3e77c99abd47b1d22ccae33c0312b4338253af0ff10825dc2796fc42864142c91324d349677098bcd0c156a9229c04d3ce8a08808b6eb702624c918722e3acc4
diff --git a/mail-filter/rspamd/rspamd-1.7.5.ebuild b/mail-filter/rspamd/rspamd-1.7.5.ebuild
new file mode 100644
index 000000000000..1a20cc22321c
--- /dev/null
+++ b/mail-filter/rspamd/rspamd-1.7.5.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+if [[ ${PV} == *9999 ]] ; then
+	SCM="git-r3"
+	EGIT_REPO_URI="https://github.com/vstakhov/rspamd.git"
+fi
+
+inherit cmake-utils user systemd pax-utils ${SCM}
+
+DESCRIPTION="Rapid spam filtering system"
+HOMEPAGE="https://github.com/vstakhov/rspamd"
+
+if [[ ${PV} == *9999 ]] ; then
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/vstakhov/rspamd/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="cpu_flags_x86_ssse3 fann gd jemalloc +jit libressl pcre2 +torch"
+REQUIRED_USE="torch? ( jit )"
+
+RDEPEND="!libressl? ( dev-libs/openssl:0=[-bindist] )
+	libressl? ( dev-libs/libressl:0= )
+	fann? ( sci-mathematics/fann )
+	pcre2? ( dev-libs/libpcre2[jit=] )
+	!pcre2? ( dev-libs/libpcre[jit=] )
+	jit? ( dev-lang/luajit:2 )
+	jemalloc? ( dev-libs/jemalloc )
+	dev-libs/libevent
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	<dev-util/ragel-7.0
+	sys-apps/file
+	gd? ( media-libs/gd[jpeg] )
+	dev-libs/icu
+	cpu_flags_x86_ssse3? ( dev-libs/hyperscan )"
+DEPEND="dev-util/ragel
+	${RDEPEND}"
+
+QA_MULTILIB_PATHS="usr/lib/rspamd/.*"
+
+pkg_setup() {
+	enewgroup rspamd
+	enewuser rspamd -1 -1 /var/lib/rspamd rspamd
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCONFDIR=/etc/rspamd
+		-DRUNDIR=/var/run/rspamd
+		-DDBDIR=/var/lib/rspamd
+		-DLOGDIR=/var/log/rspamd
+		-DENABLE_LUAJIT=$(usex jit ON OFF)
+		-DENABLE_FANN=$(usex fann ON OFF)
+		-DENABLE_GD=$(usex gd ON OFF)
+		-DENABLE_PCRE2=$(usex pcre2 ON OFF)
+		-DENABLE_JEMALLOC=$(usex jemalloc ON OFF)
+		-DENABLE_HYPERSCAN=$(usex cpu_flags_x86_ssse3 ON OFF)
+		-DENABLE_TORCH=$(usex torch ON OFF)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	newinitd "${FILESDIR}/rspamd.init-r5" rspamd
+
+	# Remove mprotect for JIT support
+	if use jit; then
+		pax-mark m "${ED}"/usr/bin/rspamd-* "${ED}"/usr/bin/rspamadm-* || die
+	fi
+
+	keepdir /var/lib/rspamd
+	keepdir /var/log/rspamd
+
+	fowners rspamd:rspamd /var/lib/rspamd /var/log/rspamd
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/rspamd.logrotate" rspamd
+
+	systemd_newunit rspamd.service rspamd.service
+}
diff --git a/mail-filter/rspamd/rspamd-9999.ebuild b/mail-filter/rspamd/rspamd-9999.ebuild
index 6c3a653743ec..1a20cc22321c 100644
--- a/mail-filter/rspamd/rspamd-9999.ebuild
+++ b/mail-filter/rspamd/rspamd-9999.ebuild
@@ -1,18 +1,30 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=6
 
-inherit cmake-utils user systemd git-r3 pax-utils
+if [[ ${PV} == *9999 ]] ; then
+	SCM="git-r3"
+	EGIT_REPO_URI="https://github.com/vstakhov/rspamd.git"
+fi
+
+inherit cmake-utils user systemd pax-utils ${SCM}
 
 DESCRIPTION="Rapid spam filtering system"
 HOMEPAGE="https://github.com/vstakhov/rspamd"
-EGIT_REPO_URI="https://github.com/vstakhov/rspamd.git"
+
+if [[ ${PV} == *9999 ]] ; then
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/vstakhov/rspamd/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS=""
-IUSE="fann +gd jemalloc +jit libressl pcre2"
+IUSE="cpu_flags_x86_ssse3 fann gd jemalloc +jit libressl pcre2 +torch"
+REQUIRED_USE="torch? ( jit )"
 
 RDEPEND="!libressl? ( dev-libs/openssl:0=[-bindist] )
 	libressl? ( dev-libs/libressl:0= )
@@ -24,10 +36,11 @@ RDEPEND="!libressl? ( dev-libs/openssl:0=[-bindist] )
 	dev-libs/libevent
 	dev-db/sqlite:3
 	dev-libs/glib:2
-	dev-util/ragel
+	<dev-util/ragel-7.0
 	sys-apps/file
 	gd? ( media-libs/gd[jpeg] )
-	dev-libs/icu"
+	dev-libs/icu
+	cpu_flags_x86_ssse3? ( dev-libs/hyperscan )"
 DEPEND="dev-util/ragel
 	${RDEPEND}"
 
@@ -46,24 +59,26 @@ src_configure() {
 		-DLOGDIR=/var/log/rspamd
 		-DENABLE_LUAJIT=$(usex jit ON OFF)
 		-DENABLE_FANN=$(usex fann ON OFF)
+		-DENABLE_GD=$(usex gd ON OFF)
 		-DENABLE_PCRE2=$(usex pcre2 ON OFF)
 		-DENABLE_JEMALLOC=$(usex jemalloc ON OFF)
-		-DENABLE_GD=$(usex gd ON OFF)
+		-DENABLE_HYPERSCAN=$(usex cpu_flags_x86_ssse3 ON OFF)
+		-DENABLE_TORCH=$(usex torch ON OFF)
 	)
 	cmake-utils_src_configure
 }
 
 src_install() {
 	cmake-utils_src_install
-	newinitd "${FILESDIR}/rspamd.init-r2" rspamd
+	newinitd "${FILESDIR}/rspamd.init-r5" rspamd
 
 	# Remove mprotect for JIT support
 	if use jit; then
 		pax-mark m "${ED}"/usr/bin/rspamd-* "${ED}"/usr/bin/rspamadm-* || die
 	fi
 
-	dodir /var/lib/rspamd
-	dodir /var/log/rspamd
+	keepdir /var/lib/rspamd
+	keepdir /var/log/rspamd
 
 	fowners rspamd:rspamd /var/lib/rspamd /var/log/rspamd