media-gfx/imagemagick: Bump to versions 6.7.8.3 and 7.0.5.4

Also removed q64 USE flag as requested in bug #602044.

Package-Manager: Portage-2.3.5, Repoman-2.3.2

3 files changed, 179 insertions, 3 deletions

diff --git a/media-gfx/imagemagick/Manifest b/media-gfx/imagemagick/Manifest
index f0793156a78d..ea595708b3df 100644
--- a/media-gfx/imagemagick/Manifest
+++ b/media-gfx/imagemagick/Manifest
@@ -1,4 +1,5 @@
 DIST ImageMagick-6.9.7-4.tar.xz 8797776 SHA256 68842c55ed9c958b84aae17974961cefff4212bf7146f09fd15c09dbdc2d9629 SHA512 9ee9cf01c486575183a67e418bdbdcf4ac2b7ea2f9ff033db6a74f8271af0567da00f020dd8c18e042221d20444bed21d5d5256944ddeaf9916b62bf1844acf6 WHIRLPOOL 7c75006dafd28bb0fe02e130b4fcbae5fe54c6fbfdb29ba6b49796a14354e7aeb56b80c498eb57a4a8c7b383af025406dfeba66735ba89fd35d61125b51e7d41
 DIST ImageMagick-6.9.7-8.tar.xz 8793588 SHA256 6276d92726240c2ced8f6db7d348e0ac13daddfe36b9f6d9b4afb3c9043ed8d2 SHA512 9c63e4cb61d7b9e6fae700f6392d31aedd4a16b0ca69d7dc5ecc92ffdc9e60b98107e49991bc255e492725525b9270cc14f03a95deb95e060329ddc5adb1e8b5 WHIRLPOOL efde5385b6f0f528be23d839689951141fb4c444efa1eb7161b36c9e62b0b1f2fba4005838d92e199dc1a6da5d0c20b7424e780e127a21545a04604434b71ee2
 DIST ImageMagick-6.9.7-9.tar.xz 8796644 SHA256 831e0ed90fd85a63d8282ba66878953a11a2b1e6912b9104f7cb5593a0891bbb SHA512 1954e14e5da1d24b44c69352444ad66aa08be2d3698d5efa7e71703064cbae56fd75eb72ba178ac8fdb4513b9eaebe87adcc6cfd19b9e11eda1b0c2704e12481 WHIRLPOOL 1a9fe789dd7b954b47c97bf33b3615784731285dea54eed684a191885748c1db3b0c66c0b2d20f294a426ce029e2b11da8e7a4b1a9fc8d12ebf5565ba3349e01
-DIST ImageMagick-7.0.5-0.tar.xz 8302276 SHA256 7362805eaa9f9b90cdb67a1f8762782bef4a42ca44939629aecad3c40305bf4c SHA512 3c0a94b9c00acc88d55fbf076c7500ac95e693554fa0f5d0932983b0f3feccba950e7aea1171ddcebe02c33917bf473896911d360b28b7cb20e5509fecbed554 WHIRLPOOL bddc2b284f2e607368d178b1b5ca26c12b4ffb800f953a5e6217171d4c0ed60deef705309466216a7f6dee7f53b630cf3ce69da6233d80145c8dd3675ec8cfd9
+DIST ImageMagick-6.9.8-3.tar.xz 8819084 SHA256 5dd5804f803d01f0c0c6fc0f3da68cc8e4c638b5ff56770f8481bbe202411316 SHA512 78d467a3d6f38d9b2f30d9d5154a45396a082e7c31119e37a3646080fbc3a87447e9fd73ffbdcc8cf45e9370bdab963d7e5b674d5933ac6d52e017371d7c1460 WHIRLPOOL 80ad8fe7afd7a564739426d1e8eee8d85900c420a07a1edc7ef047958537c0fbd5674e9f3385cc7448e903b4ebd08c24e21bdf3e0615d42614a740df7abba914
+DIST ImageMagick-7.0.5-4.tar.xz 8316148 SHA256 4a1dde5bdfec0fc549955a051be25b7ff96dfb192060997699e43c7ce0f06ab2 SHA512 4f2af87c3da5723b1b8030faf37c7b3a09f25301749f9b5c35c175b825c5f8758f29d8d36bb0acb285d2beae13aa45d906455cefec37a247c039ba98222b41ef WHIRLPOOL 8a30a7cc27666b5f7f5bd349bc06face8a836d7bce9e99a17782333e3eb54257a6635e47da791e3264d5fd1961c1558bbc3490daf93380fd5cfa62e763866e8d
diff --git a/media-gfx/imagemagick/imagemagick-7.0.5.0.ebuild b/media-gfx/imagemagick/imagemagick-6.9.8.3.ebuild
index 6fcc59e6e315..c1082ae7128d 100644
--- a/media-gfx/imagemagick/imagemagick-7.0.5.0.ebuild
+++ b/media-gfx/imagemagick/imagemagick-6.9.8.3.ebuild
@@ -14,7 +14,7 @@ SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
 LICENSE="imagemagick"
 SLOT="0/${PV}"
 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
-IUSE="autotrace bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q64 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+IUSE="autotrace bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
 
 RESTRICT="perl? ( userpriv )"
 
@@ -90,7 +90,6 @@ src_configure() {
 	local depth=16
 	use q8 && depth=8
 	use q32 && depth=32
-	use q64 && depth=64
 
 	local openmp=disable
 	use openmp && { tc-has-openmp && openmp=enable; }
diff --git a/media-gfx/imagemagick/imagemagick-7.0.5.4.ebuild b/media-gfx/imagemagick/imagemagick-7.0.5.4.ebuild
new file mode 100644
index 000000000000..c1082ae7128d
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-7.0.5.4.ebuild
@@ -0,0 +1,176 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils flag-o-matic libtool multilib toolchain-funcs versionator
+
+MY_P=ImageMagick-$(replace_version_separator 3 '-')
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.imagemagick.org/"
+SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="autotrace bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+
+RESTRICT="perl? ( userpriv )"
+
+RDEPEND="
+	dev-libs/libltdl:0
+	autotrace? ( >=media-gfx/autotrace-0.31.1 )
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	jbig? ( >=media-libs/jbigkit-2:= )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
+	lcms? ( media-libs/lcms:2= )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8:0= )
+	png? ( media-libs/libpng:0= )
+	postscript? ( app-text/ghostscript-gpl )
+	raw? ( media-gfx/ufraw )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff:0= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+		)
+	webp? ( media-libs/libwebp:0= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+		)
+	xml? ( dev-libs/libxml2:= )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}
+	!media-gfx/graphicsmagick[imagemagick]
+	virtual/pkgconfig
+	X? ( x11-proto/xextproto )"
+
+REQUIRED_USE="corefonts? ( truetype )
+	test? ( corefonts )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	default
+
+	elibtoolize # for Darwin modules
+
+	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
+	shopt -s nullglob
+	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
+	if test -n "${mesa_cards}"; then
+		addpredict "${mesa_cards}"
+	fi
+	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
+	if test -n "${ati_cards}"; then
+		addpredict "${ati_cards}"
+	fi
+	shopt -u nullglob
+	addpredict /dev/nvidiactl
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+
+	local openmp=disable
+	use openmp && { tc-has-openmp && openmp=enable; }
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	CONFIG_SHELL=$(type -P bash) \
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable hdri) \
+		$(use_enable opencl) \
+		--with-threads \
+		--with-modules \
+		--with-quantum-depth=${depth} \
+		$(use_with cxx magick-plus-plus) \
+		$(use_with perl) \
+		--with-perl-options='INSTALLDIRS=vendor' \
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts \
+		$(use_with bzip2 bzlib) \
+		$(use_with X x) \
+		$(use_with zlib) \
+		$(use_with autotrace) \
+		$(use_with postscript dps) \
+		$(use_with djvu) \
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu \
+		$(use_with fftw) \
+		$(use_with fpx) \
+		$(use_with fontconfig) \
+		$(use_with truetype freetype) \
+		$(use_with postscript gslib) \
+		$(use_with graphviz gvc) \
+		$(use_with jbig) \
+		$(use_with jpeg) \
+		$(use_with jpeg2k openjp2) \
+		$(use_with lcms) \
+		$(use_with lqr) \
+		$(use_with lzma) \
+		$(use_with openexr) \
+		$(use_with pango) \
+		$(use_with png) \
+		$(use_with svg rsvg) \
+		$(use_with tiff) \
+		$(use_with webp) \
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts) \
+		$(use_with wmf) \
+		$(use_with xml) \
+		--${openmp}-openmp \
+		--with-gcc-arch=no-automagic
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}/coders/.libs:${S}/filters/.libs:${S}/Magick++/lib/.libs:${S}/magick/.libs:${S}/wand/.libs" \
+	emake check
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt ChangeLog
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+
+	if use opencl; then
+		cat <<-EOF > "${T}"/99${PN}
+		SANDBOX_PREDICT="/dev/nvidiactl:/dev/ati/card:/dev/dri/card"
+		EOF
+
+		insinto /etc/sandbox.d
+		doins "${T}"/99${PN} #472766
+	fi
+
+	insinto /usr/share/${PN}
+	doins config/*icm
+}