media-libs/libopenmpt: Version bump to 0.6.0

Signed-off-by: James Le Cuirot <chewi@gentoo.org>

2 files changed, 62 insertions, 0 deletions

diff --git a/media-libs/libopenmpt/Manifest b/media-libs/libopenmpt/Manifest
index 197a8eaf9e90..28104baf1634 100644
--- a/media-libs/libopenmpt/Manifest
+++ b/media-libs/libopenmpt/Manifest
@@ -1 +1,2 @@
 DIST libopenmpt-0.5.14+release.autotools.tar.gz 1446898 BLAKE2B ab6ff8db2e19d859fecca882aea3e569b58d96d5055ec0dd42494a7eb38fefa9c8b88f4700d354de71346c71c6d9a96327db1c2b7b48e227928dcba0ce7347d6 SHA512 8897549c18afb57c5bf54f4dd8a1d80983829bca958052d76cda1315ef4a37f4201575817b7cedfe17a44ee79051a52aa35b26a51b554091e92c9d2dcf5924a3
+DIST libopenmpt-0.6.0+release.autotools.tar.gz 1506911 BLAKE2B 44cf8c5f725d2b11409d23e293dca0c151cad17c029da7f70a22366e75baa1b49b763f67d617d84a142efd3933b90344ccca5d881e5c724e2cfe0210170593dc SHA512 8da6cf1f2dbf683c32f45cbf884784360cced5e21f9862c96a1a679bd90b36be9a7cc59accbf82271a804722986cb81e75915f6564aeaaa248ed3e967dfdfb1a
diff --git a/media-libs/libopenmpt/libopenmpt-0.6.0.ebuild b/media-libs/libopenmpt/libopenmpt-0.6.0.ebuild
new file mode 100644
index 000000000000..ecc623d23085
--- /dev/null
+++ b/media-libs/libopenmpt/libopenmpt-0.6.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib-minimal
+
+MY_P="libopenmpt-${PV}+release.autotools"
+DESCRIPTION="Library to decode tracked music files (modules)"
+HOMEPAGE="https://lib.openmpt.org/libopenmpt/"
+SRC_URI="https://lib.openmpt.org/files/libopenmpt/src/${MY_P}.tar.gz"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~riscv ~x86"
+IUSE="examples mp3 ogg static-libs test vorbis zlib"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	mp3? ( media-sound/mpg123[${MULTILIB_USEDEP}] )
+	ogg? ( media-libs/libogg[${MULTILIB_USEDEP}] )
+	vorbis? ( media-libs/libvorbis[${MULTILIB_USEDEP}] )
+	zlib? ( sys-libs/zlib[${MULTILIB_USEDEP}] )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+ECONF_SOURCE="${S}"
+
+multilib_src_configure() {
+	# A lot of these optional dependencies relate to openmpt123, which
+	# we package separately, so we disable them here.
+	econf \
+		$(use_enable static-libs static) \
+		--disable-openmpt123 \
+		--disable-examples \
+		$(use_enable test tests) \
+		--disable-doxygen-doc \
+		$(use_with zlib) \
+		$(use_with mp3 mpg123) \
+		$(use_with ogg) \
+		$(use_with vorbis) \
+		$(use_with vorbis vorbisfile) \
+		--without-pulseaudio \
+		--without-portaudio \
+		--without-portaudiocpp \
+		--without-sdl2 \
+		--without-sndfile \
+		--without-flac
+}
+
+multilib_src_install_all() {
+	rm -f \
+		"${ED}"/usr/*/*.la \
+		"${ED}"/usr/share/doc/${P}/LICENSE || die
+
+	if ! use examples; then
+		rm -r "${ED}"/usr/share/doc/${P}/examples || die
+	fi
+}