proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 51 insertions, 0 deletions

diff --git a/media-libs/lvtk/lvtk-1.2.0.ebuild b/media-libs/lvtk/lvtk-1.2.0.ebuild
new file mode 100644
index 000000000000..b5a3bb13143f
--- /dev/null
+++ b/media-libs/lvtk/lvtk-1.2.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="threads(+)"
+inherit python-single-r1 waf-utils
+
+DESCRIPTION="A set of C++ wrappers around the LV2 C API"
+HOMEPAGE="http://lvtoolkit.org/"
+SRC_URI="https://github.com/lvtk/lvtk/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc examples +gtk2 +tools"
+
+RDEPEND="media-libs/lv2
+	>=dev-libs/boost-1.40.0
+	gtk2? ( dev-cpp/gtkmm:2.4 )"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	doc? ( app-doc/doxygen
+		media-gfx/graphviz )
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_configure() {
+	local mywafconfargs=(
+		"--docdir=${EPREFIX}/usr/share/doc/${PF}"
+		"--lv2dir=${EPREFIX}/usr/$(get_libdir)/lv2"
+	)
+	use debug    && mywafconfargs+=( "--debug" )
+	use doc      && mywafconfargs+=( "--docs" )
+	use examples || mywafconfargs+=( "--disable-examples" )
+	use tools    || mywafconfargs+=( "--disable-tools" )
+	use gtk2     || mywafconfargs+=( "--disable-ui" )
+	waf-utils_src_configure ${mywafconfargs[@]}
+}
+
+src_install() {
+	waf-utils_src_install
+
+	# It does not respect docdir properly, reported upstream
+	if use doc; then
+		mv "${ED}/usr/share/doc/${PF}/lvtk-1.0/html" "${ED}/usr/share/doc/${PF}/html"
+		rmdir "${ED}/usr/share/doc/${PF}/lvtk-1.0"
+	fi
+}