media-sound/guitarix: bump to 0.43.1 + updated live

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

3 files changed, 97 insertions, 6 deletions

diff --git a/media-sound/guitarix/Manifest b/media-sound/guitarix/Manifest
index 382ae905b964..0abe7c7d4016 100644
--- a/media-sound/guitarix/Manifest
+++ b/media-sound/guitarix/Manifest
@@ -1 +1,2 @@
 DIST guitarix2-0.42.1.tar.xz 71825372 BLAKE2B 06b2a19d68e77c622eea222e3f0658d9f89c6c8377e9b0442d581e14342f82f97948ca0ebb7ff40f4abd6cab0c9ba582fa6f43f74cad5e112d2e762445f2ab43 SHA512 66a71b4d66e0cbcff7feeceae6317c016e497626c9fde3ca44e1f06e42d9021b2857151660c1c49832cc8e6f2aa27de68dfea67d4e896c7e89f84865f8ba1eb0
+DIST guitarix2-0.43.1.tar.xz 71742288 BLAKE2B bfa72a20f5fe1bdd08162e283f7074f6bcd6b4d6ccb1771f0351e60802ebf030f8f6627d2480ccd2e5972215847edd62bff38c338723fd0bf2504b9b2cee5101 SHA512 30e56d863308cea18bb4af6f71d3e8d852662b4252c998507a1c3de9a2d97fe1c4ecb525bd35ef8e176b5cb5138806553cba157c1aa6cb14e48fe0bbea8a7def
diff --git a/media-sound/guitarix/guitarix-0.43.1.ebuild b/media-sound/guitarix/guitarix-0.43.1.ebuild
new file mode 100644
index 000000000000..d7de3341b7f3
--- /dev/null
+++ b/media-sound/guitarix/guitarix-0.43.1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 2019-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..10} )
+PYTHON_REQ_USE='threads(+)'
+
+inherit python-any-r1 waf-utils xdg
+
+MY_P="${PN}2-${PV}"
+
+DESCRIPTION="Virtual guitar amplifier for Linux"
+HOMEPAGE="https://guitarix.org/"
+SRC_URI="mirror://sourceforge/guitarix/guitarix/${MY_P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="bluetooth debug lv2 nls nsm +standalone zeroconf"
+REQUIRED_USE="|| ( lv2 standalone )"
+
+DEPEND="
+	dev-cpp/eigen:3
+	dev-cpp/glibmm:2
+	dev-cpp/gtkmm:3.0
+	dev-libs/glib:2
+	media-libs/libsndfile
+	media-libs/zita-convolver:=
+	media-libs/zita-resampler
+	net-misc/curl
+	sci-libs/fftw:3.0=
+	x11-libs/gtk+:3
+	lv2? ( media-libs/lv2 )
+	standalone? (
+		dev-libs/boost:=
+		media-libs/liblrdf
+		media-libs/lilv
+		virtual/jack
+		bluetooth? ( net-wireless/bluez )
+		nsm? ( media-libs/liblo )
+		zeroconf? ( net-dns/avahi )
+	)
+"
+# roboto fonts are required for correct ui rendering
+RDEPEND="
+	${DEPEND}
+	standalone? (
+		media-fonts/roboto
+	)
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	standalone? (
+		dev-lang/sassc
+		nls? (
+			dev-util/intltool
+			sys-devel/gettext
+		)
+	)
+"
+
+DOCS=( changelog README )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.41.0-nostrip.patch
+)
+
+src_configure() {
+	local myconf=(
+		--cxxflags-debug=""
+		--cxxflags-release="-DNDEBUG"
+		--ldflags="${LDFLAGS}"
+		--enable-lfs
+		--lib-dev
+		--no-desktop-update
+		--no-faust
+		--no-ldconfig
+		--shared-lib
+		$(use_enable nls)
+		$(usex bluetooth "" "--no-bluez")
+		$(usex debug "--debug" "")
+		$(usex lv2 "--lv2dir=${EPREFIX}/usr/$(get_libdir)/lv2" "--no-lv2 --no-lv2-gui")
+		$(usex nsm "" "--no-nsm")
+		$(usex standalone "" "--no-standalone")
+		$(usex zeroconf "" "--no-avahi")
+	)
+	waf-utils_src_configure "${myconf[@]}"
+}
diff --git a/media-sound/guitarix/guitarix-9999.ebuild b/media-sound/guitarix/guitarix-9999.ebuild
index 766f8d088f1c..ac32a3ca36c9 100644
--- a/media-sound/guitarix/guitarix-9999.ebuild
+++ b/media-sound/guitarix/guitarix-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 2019-2020 Gentoo Authors
+# Copyright 2019-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{7,8,9} )
+PYTHON_COMPAT=( python3_{7..10} )
 PYTHON_REQ_USE='threads(+)'
 
 inherit python-any-r1 waf-utils xdg git-r3
@@ -26,11 +26,11 @@ DEPEND="
 	dev-cpp/glibmm:2
 	dev-cpp/gtkmm:3.0
 	dev-libs/glib:2
-	>=media-libs/libsndfile-1.0.17
-	>=media-libs/zita-convolver-3:=
+	media-libs/libsndfile
+	media-libs/zita-convolver:=
 	media-libs/zita-resampler
-	>=net-misc/curl-7.26.0
-	>=sci-libs/fftw-3.3.8:3.0=
+	net-misc/curl
+	sci-libs/fftw:3.0=
 	x11-libs/gtk+:3
 	lv2? ( media-libs/lv2 )
 	standalone? (