media-sound/qmmp: Bump to version 1.1.7

Package-Manager: Portage-2.3.3, Repoman-2.3.1

2 files changed, 128 insertions, 0 deletions

diff --git a/media-sound/qmmp/Manifest b/media-sound/qmmp/Manifest
index e48cfa7acfcd..c9b4712e3316 100644
--- a/media-sound/qmmp/Manifest
+++ b/media-sound/qmmp/Manifest
@@ -3,3 +3,4 @@ DIST qmmp-0.10.6.tar.bz2 1341977 SHA256 9ec1df1128182dfe1d5686bfb857148577f4f2f1
 DIST qmmp-1.0.10.tar.bz2 1107784 SHA256 02bcd01b1d8f6ca8b805a5deaeaa059ee44a38fafd20bec7ee3560a021250ee3 SHA512 45231ef8b1f0a0825336752fe9314cc0df1b937ebcf85b18c89c66e52f38cf69583eccd8ffcf92d89add11643e1f40ccf0fe720fd6279f3cf4f73db336d4d59b WHIRLPOOL 0bb7d873e58b8cdbbb71576af3080031fc0e03cc3fc3153812e2a105bad40f02ac4a3838454aef5551890e278d050bbe04caf0e77ddb1cd3b43f7fd2c77cd5e7
 DIST qmmp-1.1.5.tar.bz2 1132552 SHA256 9b1288f432799980a5d58d131b56b4b590055d7e66c5fe50e9199b9daa35ddbd SHA512 9117e42fe3e74eb28c147ec98db5a5825b6c027b91ff5a9e9db48edc23b98745cfdeaf15139a48465e7607028d0a1835ab707f2e0b3749487c2e204a0ca511a7 WHIRLPOOL 0a8e75ccd0932f7e2dd95401849eb7ec88cdaa2a79b62d470319364b3e319640417359425da56cda7c31021c0a4247bca2984462fedfdc9b9edf082ce74bfbcc
 DIST qmmp-1.1.6.tar.bz2 1133591 SHA256 aff540547ed1e804b964edcb1eeb418c12906a88ab07e44fa4d88b066cd81015 SHA512 1bef5e6414021e0dfb213bc83818004b66b81cba81c0f4b53233acc9cf85cbf1f2f7c7bf15891f744fb9822e6ffabf16c87625617525bca5911cfcc99cf86eab WHIRLPOOL 129e429670280b2833c820ccd7174c2d263511bef71fdf614be69c95df6ff32f18447d854b7340fd7563543b9be24caf7ace6076db386e447a65a37c956e21de
+DIST qmmp-1.1.7.tar.bz2 1135005 SHA256 464f79d9a54e6456c5abcb570d7f062e48d3eaa3d60ad2b09c58bc62af5b87a7 SHA512 058187d34b848c0917077a167bcb52c63e39b5150409295ea658484d99fcd5582f7871979d3d3eea40aa97f0d9bf2a2d72ae721b827bcc0366b1bbc652aa3a72 WHIRLPOOL 1c1f22a22329619f63a1a24590b41b352d398bb4653117c81918b2e940e887c6aaa06f178674a97893de7418673022bdc800a09643d3fb38096f6dc78b7774c3
diff --git a/media-sound/qmmp/qmmp-1.1.7.ebuild b/media-sound/qmmp/qmmp-1.1.7.ebuild
new file mode 100644
index 000000000000..6249311e7b3d
--- /dev/null
+++ b/media-sound/qmmp/qmmp-1.1.7.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit cmake-utils
+[ "$PV" == "9999" ] && inherit subversion
+
+DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com"
+if [ "$PV" != "9999" ]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	QMMP_DEV_BRANCH="1.1"
+	ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="analyzer aac +alsa bs2b cdda cover crossfade cue curl enca ffmpeg flac jack game kde ladspa
+lyrics +mad midi mms modplug mplayer mpris musepack notifier opus oss projectm
+pulseaudio qsui scrobbler sndfile soxr stereo tray udisks +vorbis wavpack"
+
+RDEPEND="media-libs/taglib
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	alsa? ( media-libs/alsa-lib )
+	bs2b? ( media-libs/libbs2b )
+	cdda? ( dev-libs/libcdio-paranoia )
+	cue? ( media-libs/libcue )
+	curl? ( net-misc/curl )
+	aac? ( media-libs/faad2 )
+	enca? ( app-i18n/enca )
+	flac? ( media-libs/flac )
+	game? ( media-libs/game-music-emu )
+	ladspa? ( media-libs/ladspa-cmt )
+	mad? ( media-libs/libmad )
+	midi? ( media-sound/wildmidi )
+	mms? ( media-libs/libmms )
+	mplayer? ( media-video/mplayer )
+	mpris? ( dev-qt/qtdbus:5 )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	modplug? ( >=media-libs/libmodplug-0.8.4 )
+	vorbis? ( media-libs/libvorbis
+		media-libs/libogg )
+	jack? ( media-sound/jack-audio-connection-kit
+		media-libs/libsamplerate )
+	ffmpeg? ( virtual/ffmpeg )
+	opus? ( media-libs/opusfile )
+	projectm? ( media-libs/libprojectm
+		dev-qt/qtopengl:5
+		dev-qt/qtgui:5[-gles2] )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	wavpack? ( media-sound/wavpack )
+	scrobbler? ( net-misc/curl )
+	sndfile? ( media-libs/libsndfile )
+	soxr? ( media-libs/soxr )
+	udisks? ( sys-fs/udisks:2 )"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5"
+
+DOCS="AUTHORS ChangeLog README"
+
+CMAKE_IN_SOURCE_BUILD="1"
+
+src_prepare() {
+	if has_version dev-libs/libcdio-paranoia; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+	fi
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DUSE_ALSA="$(usex alsa)"
+		-DUSE_AAC="$(usex aac)"
+		-DUSE_ANALYZER="$(usex analyzer)"
+		-DUSE_BS2B="$(usex bs2b)"
+		-DUSE_CDA="$(usex cdda)"
+		-DUSE_CROSSFADE="$(usex crossfade)"
+		-DUSE_COVER="$(usex cover)"
+		-DUSE_CUE="$(usex cue)"
+		-DUSE_CURL="$(usex curl)"
+		-DUSE_ENCA="$(usex enca)"
+		-DUSE_FFMPEG="$(usex ffmpeg)"
+		-DUSE_FLAC="$(usex flac)"
+		-DUSE_GME="$(usex game)"
+		-DUSE_HAL=OFF
+		-DUSE_JACK="$(usex jack)"
+		-DUSE_KDENOTIFY="$(usex kde)"
+		-DUSE_LADSPA="$(usex ladspa)"
+		-DUSE_LYRICS="$(usex lyrics)"
+		-DUSE_MAD="$(usex mad)"
+		-DUSE_MIDI="$(usex midi)"
+		-DUSE_MPLAYER="$(usex mplayer)"
+		-DUSE_MMS="$(usex mms)"
+		-DUSE_MODPLUG="$(usex modplug)"
+		-DUSE_MPRIS="$(usex mpris)"
+		-DUSE_MPC="$(usex musepack)"
+		-DUSE_NOTIFIER="$(usex notifier)"
+		-DUSE_OPUS="$(usex opus)"
+		-DUSE_OSS="$(usex oss)"
+		-DUSE_PROJECTM="$(usex projectm)"
+		-DUSE_PULSE="$(usex pulseaudio)"
+		-DUSE_QSUI="$(usex qsui)"
+		-DUSE_SCROBBLER="$(usex scrobbler)"
+		-DUSE_SNDFILE="$(usex sndfile)"
+		-DUSE_SOXR="$(usex soxr)"
+		-DUSE_STEREO="$(usex stereo)"
+		-DUSE_STATICON="$(usex tray)"
+		-DUSE_UDISKS2="$(usex udisks)"
+		-DUSE_VORBIS="$(usex vorbis)"
+		-DUSE_WAVPACK="$(usex wavpack)"
+	)
+
+	cmake-utils_src_configure
+}