media-sound/strawberry: bump to 1.0.8 + updated live

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

3 files changed, 126 insertions, 5 deletions

diff --git a/media-sound/strawberry/Manifest b/media-sound/strawberry/Manifest
index e09411fb43b9..9a9fb0f12cfb 100644
--- a/media-sound/strawberry/Manifest
+++ b/media-sound/strawberry/Manifest
@@ -1 +1,2 @@
 DIST strawberry-1.0.7.tar.xz 11216436 BLAKE2B f7bc53f33be53fb9d947ea4f4c29827cc4248b0249904f2e48cbd9e4440de1f7f866d83c9fddc92cfb6f56b050c4dc40f0ad5e67a58c2a75e47a9d666847e9b3 SHA512 9bf092c3990ae0c2ce63074c7f6076ccab896ae915c4ee255a7fbb6534d50467648f3e96bc029075acfd50515c45ade867e55518d9a68ec9c10a741e1976d64f
+DIST strawberry-1.0.8.tar.xz 11222136 BLAKE2B b11b4a082eb2c2d180d7d217884ac498c692df1d76e54ca41e83ea3ab456c4920d3348ee0b154f02d22902b84263fb0afb86c5e125d669fc54b6ffce1719abb3 SHA512 7d43a80d4aac16379929e147a4cc7af8b2866a3a14adee8716ff89ff255859eca197f448ff605e255f0d3d74a8e0d1babf4534cfd58b5247533c37dfae6f96e3
diff --git a/media-sound/strawberry/strawberry-1.0.8.ebuild b/media-sound/strawberry/strawberry-1.0.8.ebuild
new file mode 100644
index 000000000000..fac9c644eb35
--- /dev/null
+++ b/media-sound/strawberry/strawberry-1.0.8.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic plocale xdg
+
+PLOCALES="ca cs de es es_AR es_ES es_MX fi fr hu id it ja ko nb nl pl pt_BR ru sv uk zh_CN"
+
+DESCRIPTION="Modern music player and library organizer based on Clementine and Qt"
+HOMEPAGE="https://www.strawberrymusicplayer.org/"
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/strawberrymusicplayer/strawberry"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/strawberrymusicplayer/strawberry/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="cdda debug +gstreamer ipod moodbar mtp pulseaudio +udisks vlc"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+COMMON_DEPEND="
+	dev-db/sqlite:=
+	dev-libs/glib:2
+	dev-libs/protobuf:=
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-libs/alsa-lib
+	media-libs/taglib
+	x11-libs/libX11
+	cdda? ( dev-libs/libcdio:= )
+	gstreamer? (
+		media-libs/chromaprint:=
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+	ipod? ( media-libs/libgpod )
+	moodbar? ( sci-libs/fftw:3.0 )
+	mtp? ( media-libs/libmtp )
+	pulseaudio? ( media-sound/pulseaudio )
+	vlc? ( media-video/vlc )
+"
+# Note: sqlite driver of dev-qt/qtsql is bundled, so no sqlite use is required; check if this can be overcome someway;
+RDEPEND="${COMMON_DEPEND}
+	gstreamer? (
+		media-plugins/gst-plugins-meta:1.0
+		media-plugins/gst-plugins-soup:1.0
+		media-plugins/gst-plugins-taglib:1.0
+	)
+	mtp? ( gnome-base/gvfs[mtp] )
+	udisks? ( sys-fs/udisks:2 )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-cpp/gtest
+	dev-libs/boost
+	dev-qt/qttest:5
+"
+
+DOCS=( Changelog README.md )
+
+REQUIRED_USE="
+	cdda? ( gstreamer )
+	|| ( gstreamer vlc )
+"
+
+src_prepare() {
+	plocale_find_changes "src/translations" "" ".po"
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# spotify is not in portage
+	local mycmakeargs=(
+		-DBUILD_WERROR=OFF
+		# avoid automagically enabling of ccache (bug #611010)
+		-DCCACHE_EXECUTABLE=OFF
+		-DENABLE_GIO=ON
+		-DLINGUAS="$(plocale_get_locales)"
+		-DENABLE_AUDIOCD="$(usex cdda)"
+		-DENABLE_GSTREAMER="$(usex gstreamer)"
+		-DENABLE_LIBGPOD="$(usex ipod)"
+		-DENABLE_LIBMTP="$(usex mtp)"
+		-DENABLE_LIBPULSE="$(usex pulseaudio)"
+		-DENABLE_MOODBAR="$(usex moodbar)"
+		-DENABLE_MUSICBRAINZ="$(usex gstreamer)"
+		-DENABLE_SONGFINGERPRINTING="$(usex gstreamer)"
+		-DENABLE_UDISKS2="$(usex udisks)"
+		-DENABLE_VLC="$(usex vlc)"
+		# Disable until we have qt6 in the tree
+		-DWITH_QT6=OFF
+	)
+
+	use !debug && append-cppflags -DQT_NO_DEBUG_OUTPUT
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if use gstreamer ; then
+		elog "Note that list of supported formats is controlled by media-plugins/gst-plugins-meta "
+		elog "USE flags. You may be interested in setting aac, flac, mp3, ogg or wavpack USE flags "
+		elog "depending on your preferences"
+	fi
+}
diff --git a/media-sound/strawberry/strawberry-9999.ebuild b/media-sound/strawberry/strawberry-9999.ebuild
index af868219fe69..fac9c644eb35 100644
--- a/media-sound/strawberry/strawberry-9999.ebuild
+++ b/media-sound/strawberry/strawberry-9999.ebuild
@@ -39,17 +39,17 @@ COMMON_DEPEND="
 	dev-qt/qtwidgets:5
 	dev-qt/qtx11extras:5
 	media-libs/alsa-lib
-	>=media-libs/taglib-1.11.1_p20181028
+	media-libs/taglib
 	x11-libs/libX11
 	cdda? ( dev-libs/libcdio:= )
 	gstreamer? (
-		>=media-libs/chromaprint-1.4:=
+		media-libs/chromaprint:=
 		media-libs/gstreamer:1.0
 		media-libs/gst-plugins-base:1.0
 	)
-	ipod? ( >=media-libs/libgpod-0.8.0 )
+	ipod? ( media-libs/libgpod )
 	moodbar? ( sci-libs/fftw:3.0 )
-	mtp? ( >=media-libs/libmtp-1.0.0 )
+	mtp? ( media-libs/libmtp )
 	pulseaudio? ( media-sound/pulseaudio )
 	vlc? ( media-video/vlc )
 "
@@ -64,7 +64,7 @@ RDEPEND="${COMMON_DEPEND}
 	udisks? ( sys-fs/udisks:2 )
 "
 DEPEND="${COMMON_DEPEND}
-	>=dev-cpp/gtest-1.8.0
+	dev-cpp/gtest
 	dev-libs/boost
 	dev-qt/qttest:5
 "