media-video/gpac: bump to 0.6.1 and add X useflag

Package-Manager: portage-2.2.28
Signed-off-by: Alexis Ballier <aballier@gentoo.org>

3 files changed, 129 insertions, 5 deletions

diff --git a/media-video/gpac/Manifest b/media-video/gpac/Manifest
index dd66f6ed90a0..9651e1182e26 100644
--- a/media-video/gpac/Manifest
+++ b/media-video/gpac/Manifest
@@ -1,3 +1,4 @@
 DIST gpac-0.5.0.tar.gz 7861057 SHA256 42971ac39511a1b6d1db39af664ce887b38c8657328c88cd200d87a02de81c24 SHA512 dee7701c791c441c1f050d9591d4e4dd7bdd2908f535233b114959c9a0adc256b3d5e40f5c84fd0f8b1c6764bfe6b35ec0af6bfd1fb056d593aeedca75105278 WHIRLPOOL 1797afa09864a1e9632c121dc2076963ec5e73395abdcd76896d23dc675e03847a42d733ae9fc3bb29bd26b7b336ea0f49e6e8e79c87a0bd0458cd429a7bf271
 DIST gpac-0.5.1_pre5456.tar.xz 5938432 SHA256 81746ad1d9a8ae0a84c73652d1af5d86d9c36229b278422c13e353893893a83c SHA512 25883e32d83dc2b4649c506b86f745d2f8eaaaa75fff629b534205979aeb519a167243e62ec0d78e453d1edc27435acffd521a8c08a739cde05196f61e93ac47 WHIRLPOOL af5a89cb52802bc45edd29c6f0f5ce9f48decea16eef8a76c33c7161a6d48b3d43f1a2b4c3049d2f1f92d0c3f22b787a33c1652f42d2c0cf3b84ad58c2fb7589
 DIST gpac-0.5.2.tar.gz 9044537 SHA256 14de020482fc0452240f368564baa95a71b729980e4f36d94dd75c43ac4d9d5c SHA512 b6828953333c6615a2a57845190c246681f4d83a73e1f96f200fed6bfe97b7273ab5d30618b7782cd442e68e8c9e37971792dfd6366dcf21b3b3bdbb1a8bc979 WHIRLPOOL d3e45dd7eb7070aca8d9bbc55d235f31a2955b682f1f0ae145b14db8dda69397fb840beadd7c0631bee0560f6bb3bad23a0abbc9571bab4df323136dd1c1c122
+DIST gpac-0.6.1.tar.gz 9113143 SHA256 67d1ac8f8b3e74da0e4e38ea926dc15bca6e9941e8f366e3538abcf13c103c09 SHA512 b1409a8ebcda08c3af504d7de591528ef84f5c3d8d506dd490502e16493de11c2435ea3f5957f39100a2ce040d5e431c86a5a203f806fcc865ae4b08f6cf5595 WHIRLPOOL bd0c87841036220623021898f0b82d2364fd37c5254f58cd7db33617350f0864ce9672b8cbfa10f0d08948f2842fe9b19db9f562074c43df6d94cf2b13a7d141
diff --git a/media-video/gpac/gpac-0.6.1.ebuild b/media-video/gpac/gpac-0.6.1.ebuild
new file mode 100644
index 000000000000..55f59ffb91b2
--- /dev/null
+++ b/media-video/gpac/gpac-0.6.1.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+
+if [[ ${PV} == *9999 ]] ; then
+	SCM="git-r3"
+	EGIT_REPO_URI="https://github.com/gpac/gpac"
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/gpac/gpac/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+fi
+
+inherit eutils flag-o-matic multilib toolchain-funcs ${SCM}
+
+DESCRIPTION="GPAC is an implementation of the MPEG-4 Systems standard developed from scratch in ANSI C"
+HOMEPAGE="http://gpac.wp.mines-telecom.fr/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="a52 aac alsa debug dvb ffmpeg ipv6 jack jpeg jpeg2k mad opengl oss png
+	pulseaudio sdl ssl static-libs theora truetype vorbis xml xvid X"
+
+RDEPEND="
+	a52? ( media-libs/a52dec )
+	aac? ( >=media-libs/faad2-2.0 )
+	alsa? ( media-libs/alsa-lib )
+	dvb? ( media-tv/linuxtv-dvb-apps )
+	ffmpeg? ( virtual/ffmpeg )
+	jack? ( media-sound/jack-audio-connection-kit )
+	jpeg? ( virtual/jpeg )
+	mad? ( >=media-libs/libmad-0.15.1b )
+	opengl? ( virtual/opengl media-libs/freeglut virtual/glu )
+	>=media-libs/libogg-1.1
+	png? ( >=media-libs/libpng-1.4 )
+	vorbis? ( >=media-libs/libvorbis-1.1 )
+	theora? ( media-libs/libtheora )
+	truetype? ( >=media-libs/freetype-2.1.4 )
+	xml? ( >=dev-libs/libxml2-2.6.0 )
+	xvid? ( >=media-libs/xvid-1.0.1 )
+	sdl? ( media-libs/libsdl )
+	jpeg2k? ( media-libs/openjpeg:0 )
+	ssl? ( dev-libs/openssl )
+	pulseaudio? ( media-sound/pulseaudio )
+	X? (
+		x11-libs/libXt
+		x11-libs/libX11
+		x11-libs/libXv
+		x11-libs/libXext
+	)"
+# disabled upstream, see applications/Makefile
+# wxwidgets? ( =x11-libs/wxGTK-2.8* )
+
+DEPEND="${RDEPEND}"
+
+my_use() {
+	local flag="$1" pflag="${2:-$1}"
+	if use ${flag}; then
+		echo "--use-${pflag}=system"
+	else
+		echo "--use-${pflag}=no"
+	fi
+}
+
+src_prepare() {
+	epatch	"${FILESDIR}"/110_all_implicitdecls.patch \
+			"${FILESDIR}"/${PN}-0.5.3-static-libs.patch \
+			"${FILESDIR}"/${PN}-0.5.2-gf_isom_set_pixel_aspect_ratio.patch
+	sed -i -e "s:\(--disable-.*\)=\*):\1):" configure || die
+}
+
+src_configure() {
+	tc-export CC CXX AR RANLIB
+
+	econf \
+		--enable-svg \
+		--enable-pic \
+		--disable-amr \
+		--use-js=no \
+		--use-ogg=system \
+		$(use_enable alsa) \
+		$(use_enable debug) \
+		$(use_enable ipv6) \
+		$(use_enable jack jack yes) \
+		$(use_enable opengl) \
+		$(use_enable oss oss-audio) \
+		$(use_enable pulseaudio pulseaudio yes) \
+		$(use_enable sdl) \
+		$(use_enable ssl) \
+		$(use_enable static-libs static-lib) \
+		$(use_enable X x11) $(use_enable X x11-shm) $(use_enable X x11-xv) \
+		--disable-wx \
+		$(my_use a52) \
+		$(my_use aac faad) \
+		$(my_use dvb dvbx) \
+		$(my_use ffmpeg) \
+		$(my_use jpeg) \
+		$(my_use jpeg2k openjpeg) \
+		$(my_use mad) \
+		$(my_use png) \
+		$(my_use theora) \
+		$(my_use truetype ft) \
+		$(my_use vorbis) \
+		$(my_use xvid) \
+		--extra-cflags="${CFLAGS}" \
+		--cc="$(tc-getCC)" \
+		--libdir="/$(get_libdir)" \
+		--verbose
+}
+
+src_install() {
+	emake STRIP="true" DESTDIR="${D}" install
+	emake STRIP="true" DESTDIR="${D}" install-lib
+	dodoc AUTHORS BUGS Changelog README.md TODO
+	dodoc doc/*.txt
+	dohtml doc/*.html
+}
diff --git a/media-video/gpac/gpac-9999.ebuild b/media-video/gpac/gpac-9999.ebuild
index fb000a11407f..55f59ffb91b2 100644
--- a/media-video/gpac/gpac-9999.ebuild
+++ b/media-video/gpac/gpac-9999.ebuild
@@ -20,7 +20,8 @@ HOMEPAGE="http://gpac.wp.mines-telecom.fr/"
 
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="a52 aac alsa debug dvb ffmpeg ipv6 jack jpeg jpeg2k mad opengl oss png pulseaudio sdl ssl static-libs theora truetype vorbis xml xvid"
+IUSE="a52 aac alsa debug dvb ffmpeg ipv6 jack jpeg jpeg2k mad opengl oss png
+	pulseaudio sdl ssl static-libs theora truetype vorbis xml xvid X"
 
 RDEPEND="
 	a52? ( media-libs/a52dec )
@@ -43,10 +44,12 @@ RDEPEND="
 	jpeg2k? ( media-libs/openjpeg:0 )
 	ssl? ( dev-libs/openssl )
 	pulseaudio? ( media-sound/pulseaudio )
-	x11-libs/libXt
-	x11-libs/libX11
-	x11-libs/libXv
-	x11-libs/libXext"
+	X? (
+		x11-libs/libXt
+		x11-libs/libX11
+		x11-libs/libXv
+		x11-libs/libXext
+	)"
 # disabled upstream, see applications/Makefile
 # wxwidgets? ( =x11-libs/wxGTK-2.8* )
 
@@ -87,6 +90,7 @@ src_configure() {
 		$(use_enable sdl) \
 		$(use_enable ssl) \
 		$(use_enable static-libs static-lib) \
+		$(use_enable X x11) $(use_enable X x11-shm) $(use_enable X x11-xv) \
 		--disable-wx \
 		$(my_use a52) \
 		$(my_use aac faad) \