media-video/wireplumber: drop 0.4.11

Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 0 insertions, 128 deletions

diff --git a/media-video/wireplumber/wireplumber-0.4.11.ebuild b/media-video/wireplumber/wireplumber-0.4.11.ebuild
deleted file mode 100644
index ac3004d7449f..000000000000
--- a/media-video/wireplumber/wireplumber-0.4.11.ebuild
+++ /dev/null
@@ -1,128 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-# 1. Please regularly check (even at the point of bumping) Fedora's packaging
-# for needed backports at https://src.fedoraproject.org/rpms/wireplumber/tree/rawhide
-#
-# 2. Keep an eye on git master (for both PipeWire and WirePlumber) as things
-# continue to move quickly. It's not uncommon for fixes to be made shortly
-# after releases.
-
-LUA_COMPAT=( lua5-{3,4} )
-
-inherit lua-single meson systemd
-
-if [[ ${PV} == 9999 ]]; then
-	EGIT_REPO_URI="https://gitlab.freedesktop.org/pipewire/${PN}.git"
-	EGIT_BRANCH="master"
-	inherit git-r3
-else
-	SRC_URI="https://gitlab.freedesktop.org/pipewire/${PN}/-/archive/${PV}/${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
-fi
-
-DESCRIPTION="Replacement for pipewire-media-session"
-HOMEPAGE="https://gitlab.freedesktop.org/pipewire/wireplumber"
-
-LICENSE="MIT"
-SLOT="0/0.4"
-IUSE="elogind system-service systemd test"
-
-REQUIRED_USE="
-	${LUA_REQUIRED_USE}
-	?? ( elogind systemd )
-	system-service? ( systemd )
-"
-
-RESTRICT="!test? ( test )"
-
-# introspection? ( dev-libs/gobject-introspection ) is valid but likely only used for doc building
-BDEPEND="
-	dev-libs/glib
-	dev-util/gdbus-codegen
-	dev-util/glib-utils
-	sys-devel/gettext
-"
-
-DEPEND="
-	${LUA_DEPS}
-	>=dev-libs/glib-2.62
-	>=media-video/pipewire-0.3.53-r1:=
-	virtual/libintl
-	elogind? ( sys-auth/elogind )
-	systemd? ( sys-apps/systemd )
-"
-
-# Any dev-lua/* deps get declared like this inside RDEPEND:
-#	$(lua_gen_cond_dep '
-#		dev-lua/<NAME>[${LUA_USEDEP}]
-#	')
-RDEPEND="${DEPEND}
-	system-service? (
-		acct-user/pipewire
-		acct-group/pipewire
-	)
-"
-
-DOCS=( {NEWS,README}.rst )
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-0.4.10-config-disable-sound-server-parts.patch # defer enabling sound server parts to media-video/pipewire
-)
-
-src_configure() {
-	local emesonargs=(
-		-Ddoc=disabled # Ebuild not wired up yet (Sphinx, Doxygen?)
-		-Dintrospection=disabled # Only used for Sphinx doc generation
-		-Dsystem-lua=true # We always unbundle everything we can
-		-Dsystem-lua-version=$(ver_cut 1-2 $(lua_get_version))
-		$(meson_feature elogind)
-		$(meson_feature systemd)
-		$(meson_use system-service systemd-system-service)
-		$(meson_use systemd systemd-user-service)
-		-Dsystemd-system-unit-dir=$(systemd_get_systemunitdir)
-		-Dsystemd-user-unit-dir=$(systemd_get_userunitdir)
-		$(meson_use test tests)
-	)
-
-	meson_src_configure
-}
-
-src_install() {
-	meson_src_install
-
-	# We copy the default config, so that Gentoo tools can pick up on any
-	# updates and /etc does not end up with stale overrides.
-	# If a reflinking CoW filesystem is used (e.g. Btrfs), then the files
-	# will not actually get stored twice until modified.
-	insinto /etc
-	doins -r "${ED}"/usr/share/wireplumber
-}
-
-pkg_postinst() {
-	if systemd_is_booted ; then
-		ewarn "pipewire-media-session.service is no longer installed. You must switch"
-		ewarn "to wireplumber.service user unit before your next logout/reboot:"
-		ewarn "systemctl --user disable pipewire-media-session.service"
-		ewarn "systemctl --user --force enable wireplumber.service"
-	else
-		ewarn "Switch to WirePlumber will happen the next time gentoo-pipewire-launcher"
-		ewarn "is started (a replacement for directly calling pipewire binary)."
-		ewarn
-		ewarn "Please ensure that ${EROOT}/etc/pipewire/pipewire.conf either does not exist"
-		ewarn "or, if it does exist, that any reference to"
-		ewarn "${EROOT}/usr/bin/pipewire-media-session is commented out (begins with a #)."
-	fi
-	if use system-service; then
-		ewarn
-		ewarn "WARNING: you have enabled the system-service USE flag, which installs"
-		ewarn "the system-wide systemd units that enable WirePlumber to run as a system"
-		ewarn "service. This is more than likely NOT what you want. You are strongly"
-		ewarn "advised not to enable this mode and instead stick with systemd user"
-		ewarn "units. The default configuration files will likely not work out of"
-		ewarn "box, and you are on your own with configuration."
-		ewarn
-	fi
-}