net-im/poezio: add 0.14, update live ebuild

Thanks to Michał Górny for helping with python_test().

Signed-off-by: Florian Schmaus <flow@gentoo.org>

3 files changed, 91 insertions, 5 deletions

diff --git a/net-im/poezio/Manifest b/net-im/poezio/Manifest
index 8c63c9fa1b81..02b8eba1a8a6 100644
--- a/net-im/poezio/Manifest
+++ b/net-im/poezio/Manifest
@@ -1 +1,2 @@
 DIST poezio-0.13.1.tar.gz 632572 BLAKE2B e8d3d34c5ca8d236a5a434b4b339cab5ea7286c60db3ef5a6012d406848537b587e834b86f7b6049ee8e637a82e883b2d874134bc1f7d64106e0b0f81aab218f SHA512 6c211ef0fa2fc4bd4cce6ab896166eec6bcdc16ad9e774f4d6bf261b404c9ef68b18d934097da0e165b0cce9bd7779da520ac9c3eac30ccf8280f98ef6aa19c6
+DIST poezio-0.14.tar.gz 662379 BLAKE2B 467741d82945c084c79811d41ff85358ad236d0dcefca7e6f1f8ed5d78aa127f800d2370d624ebaf9e2eb20e1038f280c2e874694ea2b86965fe329b82c4b7d8 SHA512 6e68954a918c645592e2d2f8a265e2f2445a39e256c0525a5517e758a90cc404e066cc08d67ad0f8a3c7d6f3efd61f13a776737d110dd23df7a5f7fab54fc6b5
diff --git a/net-im/poezio/poezio-0.14.ebuild b/net-im/poezio/poezio-0.14.ebuild
new file mode 100644
index 000000000000..81e2f3ab9a0b
--- /dev/null
+++ b/net-im/poezio/poezio-0.14.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 optfeature xdg
+
+DESCRIPTION="Console XMPP client that looks like most famous IRC clients"
+HOMEPAGE="https://poez.io/"
+LICENSE="GPL-3+"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://lab.louiz.org/${PN}/${PN}.git"
+	inherit git-r3
+
+	# We build the html documentation using sphinx.
+	BDEPEND="dev-python/sphinx"
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+RDEPEND="
+	dev-python/aiodns[${PYTHON_USEDEP}]
+	dev-python/pyasn1-modules[${PYTHON_USEDEP}]
+	dev-python/pyasn1[${PYTHON_USEDEP}]
+	>=dev-python/slixmpp-1.8.2[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/Do-not-install-man-pages-and-files-in-usr-share-poez.patch"
+)
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+	# Delete unmaintained plugin which requires an excessive external dep
+	rm plugins/mpd_client.py || die
+}
+
+src_compile() {
+	distutils-r1_src_compile
+
+	if [[ -n "${EGIT_REPO_URI}" ]]; then
+		emake -C doc html
+	fi
+}
+
+# Poezio provides its own Python C extension 'poopt', which needs to be
+# correctly discovered to run the tests. See
+# https://projects.gentoo.org/python/guide/test.html#importerrors-for-c-extensions
+python_test() {
+	cd "${T}" || die
+	epytest "${S}"/test
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	doman data/poezio.1 data/poezio_logs.1
+
+	if [[ -n "${EGIT_REPO_URI}" ]]; then
+		docinto html
+		dodoc -r doc/build/html/*
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "screen autoaway support" dev-python/pyinotify
+}
diff --git a/net-im/poezio/poezio-9999.ebuild b/net-im/poezio/poezio-9999.ebuild
index 608644fde1b2..162044b8bbf3 100644
--- a/net-im/poezio/poezio-9999.ebuild
+++ b/net-im/poezio/poezio-9999.ebuild
@@ -1,16 +1,16 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-DISTUTILS_USE_SETUPTOOLS=rdepend
+DISTUTILS_USE_PEP517=setuptools
 PYTHON_COMPAT=( python3_{7..10} )
 
 inherit distutils-r1 optfeature xdg
 
 DESCRIPTION="Console XMPP client that looks like most famous IRC clients"
 HOMEPAGE="https://poez.io/"
-LICENSE="ZLIB"
+LICENSE="GPL-3+"
 SLOT="0"
 
 if [[ "${PV}" == "9999" ]]; then
@@ -28,7 +28,7 @@ RDEPEND="
 	dev-python/aiodns[${PYTHON_USEDEP}]
 	dev-python/pyasn1-modules[${PYTHON_USEDEP}]
 	dev-python/pyasn1[${PYTHON_USEDEP}]
-	>=dev-python/slixmpp-1.7.1[${PYTHON_USEDEP}]
+	>=dev-python/slixmpp-1.8.2[${PYTHON_USEDEP}]
 "
 
 PATCHES=(
@@ -51,6 +51,14 @@ src_compile() {
 	fi
 }
 
+# Poezio provides its own Python C extension 'poopt', which needs to be
+# correctly discovered to run the tests. See
+# https://projects.gentoo.org/python/guide/test.html#importerrors-for-c-extensions
+python_test() {
+	cd "${T}" || die
+	epytest "${S}"/test
+}
+
 src_install() {
 	distutils-r1_src_install