net-irc/limnoria: add 20220927

Signed-off-by: Sam Jorna <wraeth@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/net-irc/limnoria/Manifest b/net-irc/limnoria/Manifest
index 3b4d2a8fb86c..c5cd49d98cdd 100644
--- a/net-irc/limnoria/Manifest
+++ b/net-irc/limnoria/Manifest
@@ -1,3 +1,4 @@
 DIST limnoria-20220203.tar.gz 1099544 BLAKE2B fc68fb41b094978ddff159241bb4029ba8b3df2995b69f3eecf44599431cf2074a318469892c5b9c2c6660976fd7df52c76d5790b6db0ce94e390b57aa2a3e79 SHA512 50cc56885799d28ee559fffa7a3dc92189d0f41950c3e2b6062490d46c360fd18c188b64ca395963aeca62ff65f81f3536524f154e81ab9c703033e0c3ef0487
 DIST limnoria-20220427.tar.gz 1119981 BLAKE2B 3346d0576c1928cf074198afa2b2b613bc9672ea68d5f395e691f97b7aaac989a5ee8f388d41d9e767eea0c495974b066b8fc2a9a0bf3a7aa9db8c52bcabcec1 SHA512 d4f617cec32ebfc67c738b542a55d2a1cd92a287a107dc84d516a1431abe0e4f440fa7b4f2a4b7fce18f24582cfdcb2ad2ed66ff2779e6a64ba7788840c1adf3
 DIST limnoria-20220814.tar.gz 1124320 BLAKE2B f2c32a444726d7e25560a7408c11c4c9d4536823eda2e4eb7b57b880f5d3aaf5c6e560d6b912c2e4b35b04e6d4f767f66aa5bd2411b9820644bef3372a34deb6 SHA512 7a7e73c9c4583310dbe0032e2b058977c102d01f7b9bea03c505153cbc45dadb88087186c036e05b1d07c7361d3e2d077a669a857241152a6726245b8b424317
+DIST limnoria-20220927.tar.gz 1125411 BLAKE2B f10c112c59e74ad018291df770ad9ae8829f90cb57125e7be066964e9987a069ff778dc8c3e562fe2f04627c173d611f6089975d0b44c47b72a9c41fcb429983 SHA512 9e8d57c34d1ff23e1772be618d9f9a8fae909200d3002ea97a95a5ba6545781d68194c4c796fa7f8683a0f3a267566ade01dd74f26110e7e0febef8ff739d88a
diff --git a/net-irc/limnoria/limnoria-20220927.ebuild b/net-irc/limnoria/limnoria-20220927.ebuild
new file mode 100644
index 000000000000..c54f729af75e
--- /dev/null
+++ b/net-irc/limnoria/limnoria-20220927.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_IN_SOURCE_BUILD=yes # needed for tests
+inherit distutils-r1
+
+MY_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}"
+MY_PN="Limnoria"
+MY_P="${MY_PN}-${MY_PV}"
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://github.com/ProgVal/${MY_PN}.git"
+	EGIT_BRANCH="testing"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/ProgVal/${MY_PN}/archive/master-${MY_PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${MY_PN}-master-${MY_PV}"
+	KEYWORDS="~amd64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Python based extensible IRC infobot and channel bot"
+HOMEPAGE="https://docs.limnoria.net"
+LICENSE="BSD GPL-2 GPL-2+"
+SLOT="0"
+IUSE="crypt ssl test"
+RESTRICT=" !test? ( test )"
+
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/ecdsa[${PYTHON_USEDEP}]
+	dev-python/feedparser[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/PySocks[${PYTHON_USEDEP}]
+	dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	crypt? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )
+	ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )"
+BDEPEND="test? ( dev-python/mock[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	# replace "installed on ${timestamp}" with real version
+	echo "version='${MY_PV//-/.}'" > "${S}"/src/version.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	pushd "${T}" > /dev/null || die
+	PLUGINS_DIR="${BUILD_DIR}"/lib/supybot/plugins
+	EXCLUDE_PLUGINS=()
+	# intermittent failure due to issues loading libsandbox.so from LD_PRELOAD
+	# runs successfully when running the tests on the installed system
+	EXCLUDE_PLUGINS+=(
+		--exclude="${PLUGINS_DIR}/Unix"
+		--exclude="${PLUGINS_DIR}/Aka"
+		--exclude="${PLUGINS_DIR}/Misc"
+	)
+	"${EPYTHON}" "${BUILD_DIR}"/scripts/supybot-test "${BUILD_DIR}/../test" \
+		--plugins-dir="${PLUGINS_DIR}" --no-network \
+		--disable-multiprocessing "${EXCLUDE_PLUGINS[@]}" \
+		|| die "Tests failed under ${EPYTHON}"
+	popd > /dev/null || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	doman man/*
+}
+
+pkg_postinst() {
+	elog "Complete user documentation is available at https://limnoria-doc.readthedocs.org/"
+	elog ""
+	elog "Use supybot-wizard to create a configuration file."
+	elog "Run supybot </path/to/config> to use the bot."
+}