net-libs/pjproject: Version bump to 2.6.0

Package-Manager: portage-2.3.8

3 files changed, 104 insertions, 2 deletions

diff --git a/net-libs/pjproject/Manifest b/net-libs/pjproject/Manifest
index 53dd3f26279e..3d775ce2cc04 100644
--- a/net-libs/pjproject/Manifest
+++ b/net-libs/pjproject/Manifest
@@ -1 +1,2 @@
 DIST pjproject-2.5.1.tar.bz2 4180967 SHA256 c5a63bed7a0832ff53ddcd69612cf43148019d0f320b22beb5ca2223bc857dcb SHA512 7722980e5afa4b541614c4117462b0df3fff2bfec45ca5da18a7c3fce2a5dd6c628ed0bb2412da6086abd59c5ba2844bea9466f49737dbc9ca85d32ef67a2628 WHIRLPOOL 5b7845a31a3da765358f0a1b28805e39dadae06b01f94fb84809f01bddec8e5d3bfa3c0ef19be6a5dbb7519e3f5948c4bf1c73eebf3efeb609c6a3bf4598585f
+DIST pjproject-2.6.tar.bz2 4933273 SHA256 2f5a1da1c174d845871c758bd80fbb580fca7799d3cfaa0d3c4e082b5161c7b4 SHA512 48be9a80f90b1cb292c6eb0d071d889f6027f56bdd75095c510d9be2d6b5f1df5a6371617009371525ac5797dc61f5814dcc1cc11d14105e5a2576539f89293f WHIRLPOOL a7cc5fe528bc24b9f0563170297539530089202280d7640f84863ae07194c0fe1b81be8c46fb493574350e43dcfcc0f90aeb939ef2eda7940babff955c445f04
diff --git a/net-libs/pjproject/pjproject-2.5.1.ebuild b/net-libs/pjproject/pjproject-2.5.1.ebuild
index 5e24af2ecd3e..d47ae1c5b9b5 100644
--- a/net-libs/pjproject/pjproject-2.5.1.ebuild
+++ b/net-libs/pjproject/pjproject-2.5.1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2016 Gentoo Foundation
+# Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -34,7 +34,7 @@ RDEPEND="alsa? ( media-libs/alsa-lib )
 
 	ssl? ( dev-libs/openssl:= )
 
-	net-libs/libsrtp"
+	net-libs/libsrtp:0"
 DEPEND="${RDEPEND}
 	virtual/pkgconfig"
 
diff --git a/net-libs/pjproject/pjproject-2.6.ebuild b/net-libs/pjproject/pjproject-2.6.ebuild
new file mode 100644
index 000000000000..d47ae1c5b9b5
--- /dev/null
+++ b/net-libs/pjproject/pjproject-2.6.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic
+
+DESCRIPTION="Open source SIP, Media, and NAT Traversal Library"
+HOMEPAGE="http://www.pjsip.org/"
+SRC_URI="http://www.pjsip.org/release/${PV}/${P}.tar.bz2"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="GPL-2"
+SLOT="0"
+CODEC_FLAGS="g711 g722 g7221 gsm ilbc speex l16"
+VIDEO_FLAGS="sdl ffmpeg v4l2 openh264 libyuv"
+SOUND_FLAGS="alsa oss portaudio"
+IUSE="amr debug doc epoll examples ipv6 opus resample silk ssl static-libs webrtc ${CODEC_FLAGS} ${VIDEO_FLAGS} ${SOUND_FLAGS}"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	oss? ( media-libs/portaudio[oss] )
+	portaudio? ( media-libs/portaudio )
+
+	amr? ( media-libs/opencore-amr )
+	gsm? ( media-sound/gsm )
+	ilbc? ( dev-libs/ilbc-rfc3951 )
+	opus? ( media-libs/opus )
+	speex? ( media-libs/speex )
+
+	ffmpeg? ( virtual/ffmpeg:= )
+	sdl? ( media-libs/libsdl )
+	openh264? ( media-libs/openh264 )
+	resample? ( media-libs/libsamplerate )
+
+	ssl? ( dev-libs/openssl:= )
+
+	net-libs/libsrtp:0"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+REQUIRED_USE="?? ( ${SOUND_FLAGS} )"
+
+src_configure() {
+	local myconf=()
+	local videnable="--disable-video"
+	local t
+
+	use ipv6 && append-flags -DPJ_HAS_IPV6=1
+	use debug || append-flags -DNDEBUG=1
+
+	for t in ${CODEC_FLAGS}; do
+		myconf+=( $(use_enable ${t} ${t}-codec) )
+	done
+
+	for t in ${VIDEO_FLAGS}; do
+		myconf+=( $(use_enable ${t}) )
+		use "${t}" && videnable="--enable-video"
+	done
+
+	econf \
+		--enable-shared \
+		--with-external-srtp \
+		${videnable} \
+		$(use_enable epoll) \
+		$(use_with gsm external-gsm) \
+		$(use_with speex external-speex) \
+		$(use_enable speex speex-aec) \
+		$(use_enable resample) \
+		$(use_enable resample libsamplerate) \
+		$(use_enable resample resample-dll) \
+		$(use_enable alsa sound) \
+		$(use_enable oss) \
+		$(use_with portaudio external-pa) \
+		$(use_enable portaudio ext-sound) \
+		$(use_enable amr opencore-amr) \
+		$(use_enable silk) \
+		$(use_enable opus) \
+		$(use_enable ssl) \
+		$(use_enable webrtc) \
+		"${myconf[@]}"
+}
+
+src_compile() {
+	emake dep
+	emake
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	if use doc; then
+		dodoc README.txt README-RTEMS
+	fi
+
+	if use examples; then
+		insinto "/usr/share/doc/${PF}/examples"
+		doins -r pjsip-apps/src/samples
+	fi
+
+	use static-libs || rm "${D}/usr/$(get_libdir)/*.a"
+}