net-libs/signond: version bump 8.60

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Michael Palimaka <kensington@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/net-libs/signond/Manifest b/net-libs/signond/Manifest
index ce4d651c7082..01ccbe8e1f79 100644
--- a/net-libs/signond/Manifest
+++ b/net-libs/signond/Manifest
@@ -1 +1,2 @@
 DIST signond-8.59.tar.gz 281298 BLAKE2B 29b97705b6e774f65b42a7ef9a253b08b1f4caf46141e3d761aabd9ef641dbe1301ef2fac0f46d8073e815bb97bc64bfbbf4b19d9c6644e2369f3abe538a50af SHA512 b8db03127df7b62dbf046841568c12f29c48c0b3272751600637864caa1c10b05ee9abce20fa41fb8eb7133c6bb20d18ca40803077e9e7808dba5afd108a36bb
+DIST signond-8.60.tar.gz 281359 BLAKE2B 3ecd8048d8c5551c3611e48091c35a9f0fe4c972e6b4730fe1f610b4870fe86911dee04c331847deee2a50f4a04acd5a8a0d1c605d1f4f0a24272d44c289a6d3 SHA512 fb3ccc99c692506ca29d5bae39bc375ff97057734fac1551ea39105d5f8e78f3df23e01a286f73be3a606c54b40f957c3c0d985484926e57f354218e4137ff3c
diff --git a/net-libs/signond/signond-8.60.ebuild b/net-libs/signond/signond-8.60.ebuild
new file mode 100644
index 000000000000..48c9bc22dc56
--- /dev/null
+++ b/net-libs/signond/signond-8.60.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qmake-utils vcs-snapshot
+
+DESCRIPTION="Signon daemon for libaccounts-glib"
+HOMEPAGE="https://01.org/gsso/"
+SRC_URI="https://gitlab.com/accounts-sso/${PN}/-/archive/VERSION_${PV}/${PN}-VERSION_${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5
+	net-libs/libproxy
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+BDEPEND="doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	default
+
+	# remove unused dependency
+	sed -e "/xml \\\/d" -i src/signond/signond.pro || die
+
+	# install docs to correct location
+	sed -e "s|share/doc/\$\${PROJECT_NAME}|share/doc/${PF}|" -i doc/doc.pri || die
+	sed -e "/^documentation.path = /c\documentation.path = \$\${INSTALL_PREFIX}/share/doc/${PF}/\$\${TARGET}/" \
+		-i lib/plugins/doc/doc.pri || die
+	sed -e "/^documentation.path = /c\documentation.path = \$\${INSTALL_PREFIX}/share/doc/${PF}/libsignon-qt/" \
+		-i lib/SignOn/doc/doc.pri || die
+
+	# don't install example plugin
+	sed -e "/example/d" -i src/plugins/plugins.pro || die
+
+	# don't install static libs
+	sed -e "/libsignon-qt-static.pro/s/^/#/" -i lib/SignOn/SignOn.pro || die
+
+	# make tests optional
+	use test || sed -i -e '/^SUBDIRS/s/tests//' signon.pro || die "couldn't disable tests"
+
+	# make docs optional
+	use doc || sed -e "/include(\s*doc\/doc.pri\s*)/d" -i \
+		signon.pro -i lib/SignOn/SignOn.pro lib/plugins/plugins.pro || die
+}
+
+src_configure() {
+	eqmake5 LIBDIR=/usr/$(get_libdir)
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+}