net-misc/bird: 1.6.6 & 2.0.4 version bumps

New init script by Alarig Le Lay fixes bad behaviour for 2.x daemons,
by rewriting in a different style as suggested by Michael Orlitzky.
1.6.6 contains several bugfixes related to route propagation.
2.0.4 contains:
 * OSPF: DN-bit handling (RFC 4576)
 * Preferred route counters are back
 * Important BGP bugfix
 * Several bugfixes related to route propagation
 * Some minor bugfixes

Closes: https://bugs.gentoo.org/682628
Bug: https://bugs.gentoo.org/622334
Suggested-By: Michael Orlitzky <mjo@gentoo.org>
Tested-by: Alarig Le Lay <alarig@swordarmor.fr>
Signed-Off-By: Tony Vroon <chainsaw@gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11

1 files changed, 68 insertions, 0 deletions

diff --git a/net-misc/bird/bird-1.6.6.ebuild b/net-misc/bird/bird-1.6.6.ebuild
new file mode 100644
index 000000000000..db540658a184
--- /dev/null
+++ b/net-misc/bird/bird-1.6.6.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="A routing daemon implementing OSPF, RIPv2 & BGP for IPv4 or IPv6"
+HOMEPAGE="http://bird.network.cz"
+SRC_URI="ftp://bird.network.cz/pub/${PN}/${P}.tar.gz"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~x64-macos"
+IUSE="+client debug ipv6"
+
+RDEPEND="client? ( sys-libs/ncurses )
+	client? ( sys-libs/readline )"
+DEPEND="sys-devel/flex
+	sys-devel/bison
+	sys-devel/m4"
+
+src_prepare() {
+	eapply_user
+	mkdir ipv6
+	tar c --exclude ipv6 . | tar x -C ipv6
+}
+
+src_configure() {
+	econf \
+		--disable-ipv6 \
+		--localstatedir="${EPREFIX}/var" \
+		$(use_enable client) \
+		$(use_enable debug)
+
+	if use ipv6; then
+		cd ipv6
+		econf \
+			--enable-ipv6 \
+			--localstatedir="${EPREFIX}/var" \
+			$(use_enable client) \
+			$(use_enable debug)
+	fi
+}
+
+src_compile() {
+	emake
+	if use ipv6; then
+		cd ipv6
+		emake
+	fi
+}
+
+src_install() {
+	if use ipv6; then
+		if use client; then
+			newbin ipv6/birdc birdc6
+		fi
+		newbin ipv6/birdcl birdcl6
+		newsbin ipv6/bird bird6
+		newinitd "${FILESDIR}/initd-${PN}-2" bird6
+	fi
+	if use client; then
+		dobin birdc
+	fi
+	dobin birdcl
+	dosbin bird
+	newinitd "${FILESDIR}/initd-${PN}-2" bird
+	dodoc doc/bird.conf.example
+}