net-misc/nextcloud-client: 3.1.2 bump

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

2 files changed, 91 insertions, 0 deletions

diff --git a/net-misc/nextcloud-client/Manifest b/net-misc/nextcloud-client/Manifest
index 92ed69099680..fdbb5c5c02dc 100644
--- a/net-misc/nextcloud-client/Manifest
+++ b/net-misc/nextcloud-client/Manifest
@@ -1,2 +1,3 @@
 DIST nextcloud-client-2.6.5.tar.gz 19134736 BLAKE2B 12defed7dc9a23622d49228c2e78586533f51d1cfd6209e263a0a8b94d307028b1afa76004768432a2bee68140602da003ef10133cd166fd3443a0a45ccccabc SHA512 fcb8ac368e064f9e9ffdc014faabb4f308045d2b047e1011e17bf2e54fa61f462f529eb48e5ec2aa638df8d9720bd7b88acef9b26aa3ba2b90e8977b3be45462
 DIST nextcloud-client-3.1.1.tar.gz 19440799 BLAKE2B ae6ef7fbff4b7b5c9a5728a30558000cd781348dd07aba068af5b123ec629e1661b52cd63b50bf45c593411866bc607dfcc3112713fa2aea3eabfda7ce969614 SHA512 1f60266ff6d413a614261ae8b6c75ba6bc5cdb534f1906039b47cb7d593d12d72013d277dc12c0bfc5c5919322438543736a7cdff056949d80e093538fd04209
+DIST nextcloud-client-3.1.2.tar.gz 19517295 BLAKE2B 75713a892816be515984cef579e09dfb58165bf1e35e73982bd59fb1cce9a0cdcc76a33a9116b85da99174f0ee4f3c425afb380df5a99d65dba82a9c6d5b3553 SHA512 bad05fab6c6d391ed40e7f9b5869f3ab3231bdba1bbb24b7222d9cace0bd96989b0b24757bf0757053a851312265aec5a4ac6f4d1c71d532152aa20ddee838a6
diff --git a/net-misc/nextcloud-client/nextcloud-client-3.1.2.ebuild b/net-misc/nextcloud-client/nextcloud-client-3.1.2.ebuild
new file mode 100644
index 000000000000..f05da2618590
--- /dev/null
+++ b/net-misc/nextcloud-client/nextcloud-client-3.1.2.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+DESCRIPTION="Desktop Syncing Client for Nextcloud"
+HOMEPAGE="https://github.com/nextcloud/desktop"
+SRC_URI="https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc dolphin libressl nautilus test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	dev-libs/qtkeychain[gnome-keyring,qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtquickcontrols2:5
+	dev-qt/qtsql:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwebengine:5[widgets]
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	!libressl? ( >=dev-libs/openssl-1.1.0:0= )
+	libressl? ( >=dev-libs/libressl-3.1:0= )
+	nautilus? ( dev-python/nautilus-python )"
+
+RDEPEND="${COMMON_DEPEND}"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+RESTRICT="!test? ( test )"
+
+S=${WORKDIR}/desktop-${PV/_/-}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DCMAKE_DISABLE_FIND_PACKAGE_Sphinx=$(usex !doc)
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF5=$(usex !dolphin)
+		-DNO_SHIBBOLETH=yes
+		-DUNIT_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+}