net-misc/youtube-dl: Version 2019.09.12.1

Package-Manager: Portage-2.3.75, Repoman-2.3.17
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index 8e1635266303..6e75ddada372 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1 +1,2 @@
 DIST youtube-dl-2019.09.01.tar.gz 3179376 BLAKE2B 422e7f7f86d6486c45c2638b81a107c1fbf1aac4c05819b5d98185a403b9ed75be520e5711f42393ed4560b5828d10b6a55a633b55fa84d110f0c323bb159374 SHA512 327ef44180e2048045884d79de20541f81a4dbcee415c3fa15bcf333674f2b6e6c6663efa532b64e4f7078449af946479c98464ff9b54642e886f8c792f0b82f
+DIST youtube-dl-2019.09.12.1.tar.gz 3180312 BLAKE2B 0fb4f6fdba490407c655645823ebdabff443e8bc0490a0c54865cc4e0d2da0fe27a9eb297e521084a412b1dacd6afb988f5c167f3643a6783bf9d4f52a49b980 SHA512 8177165cab21e83d1e1012c3d56e5182816f2367322eeea526c6d18aa74d35271a4625c6663204c0a5206976dbe32c97cdcd22b000e4e8e23a1073b474345eb3
diff --git a/net-misc/youtube-dl/youtube-dl-2019.09.12.1.ebuild b/net-misc/youtube-dl/youtube-dl-2019.09.12.1.ebuild
new file mode 100644
index 000000000000..89ac8f636eea
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2019.09.12.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=(python{2_7,3_5,3_6,3_7})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://github.com/ytdl-org/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+LICENSE="public-domain"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+RESTRICT="test"
+SLOT="0"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	|| (
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+		dev-python/pycrypto[${PYTHON_USEDEP}]
+	)
+"
+S="${WORKDIR}/${PN}"
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need avconf (media-video/libav) or"
+	elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
+	elog "videos can be retrieved in a higher quality format without sound."
+	elog "${PN} will detect whether avconv/ffmpeg is present and"
+	elog "automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}