net-misc/s6-networking: add 2.7.0.3

Signed-off-by: Petr Vaněk <arkamar@gentoo.org>

2 files changed, 62 insertions, 0 deletions

diff --git a/net-misc/s6-networking/Manifest b/net-misc/s6-networking/Manifest
index 3f01feea5204..9bb86350bfed 100644
--- a/net-misc/s6-networking/Manifest
+++ b/net-misc/s6-networking/Manifest
@@ -1 +1,2 @@
 DIST s6-networking-2.7.0.2.tar.gz 115997 BLAKE2B 24728f3b5e08eb94b295f345231a348c072c08a84d42585763bed8fe7057eeee6860b0d00f8548a86a896db98f1c4f51346b12f9361d500f962de6defe39308e SHA512 49f80c68d639f2b7ac7451ca2ace828ca4e8c1eeffec4a9b31f8157c26a87228275ea14d8b6495b0af0879a961b37910aa2b769d8db56d8731d0827c96053631
+DIST s6-networking-2.7.0.3.tar.gz 116055 BLAKE2B 1f2a6c3796aac95526fac68c8918831089eecb1536f42e4bfd85640eac8e4b0197ca03a039eb37671e1f0032419dfa4f7397b03a352b8c38c17609e75d79f09c SHA512 50d369303bd448d09a3f6431e64fb0f0b13383c92764b499ed881af3a6a8c4f779f1f9d98341943f6fdc8b18d16df444897d3750212df89efd838b6de562eede
diff --git a/net-misc/s6-networking/s6-networking-2.7.0.3.ebuild b/net-misc/s6-networking/s6-networking-2.7.0.3.ebuild
new file mode 100644
index 000000000000..7d7abc64001e
--- /dev/null
+++ b/net-misc/s6-networking/s6-networking-2.7.0.3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit optfeature toolchain-funcs
+
+DESCRIPTION="Suite of small networking utilities for Unix systems"
+HOMEPAGE="https://www.skarnet.org/software/s6-networking/"
+SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="ssl"
+
+RDEPEND="
+	dev-lang/execline:=
+	>=dev-libs/skalibs-2.14.1.0:=
+	>=net-dns/s6-dns-2.3.7.0:=
+	sys-apps/s6:=[execline]
+	ssl? ( dev-libs/libretls:= )
+"
+DEPEND="${RDEPEND}"
+
+HTML_DOCS=( doc/. )
+
+src_prepare() {
+	default
+
+	# Avoid QA warning for LDFLAGS addition
+	sed -i -e 's/.*-Wl,--hash-style=both$/:/' configure || die
+
+	sed -i -e '/AR := /d' -e '/RANLIB := /d' Makefile || die
+}
+
+src_configure() {
+	tc-export AR CC RANLIB
+
+	local myconf=(
+		--bindir=/bin
+		--dynlibdir="/$(get_libdir)"
+		--libdir="/usr/$(get_libdir)/${PN}"
+		--with-dynlib="/$(get_libdir)"
+		--with-lib="/usr/$(get_libdir)/s6"
+		--with-lib="/usr/$(get_libdir)/s6-dns"
+		--with-lib="/usr/$(get_libdir)/skalibs"
+		--with-sysdeps="/usr/$(get_libdir)/skalibs"
+		--enable-shared
+		--disable-allstatic
+		--disable-static
+		--disable-static-libc
+		$(use_enable ssl ssl libtls)
+	)
+
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	optfeature "man pages" app-doc/s6-networking-man-pages
+}