net-wireless/aircrack-ng: version bump to latest RC

Package-Manager: portage-2.2.25

3 files changed, 146 insertions, 1 deletions

diff --git a/net-wireless/aircrack-ng/Manifest b/net-wireless/aircrack-ng/Manifest
index 80ce3f85a7a9..b064311dcca8 100644
--- a/net-wireless/aircrack-ng/Manifest
+++ b/net-wireless/aircrack-ng/Manifest
@@ -1,2 +1,3 @@
 DIST aircrack-ng-1.2-rc1.tar.gz 2046476 SHA256 cf3134521e1c3d7aed4e384e3e5e7b6959e2d485bd1554474608a3a9328e35fd SHA512 897427c535846c0ede58b2f99ed469bc01f50f9b38fc70d5711261fca7342339192cc0c71a724fc04c99114db7534d825a44f09e7bc5754286ec44933a33e40d WHIRLPOOL 2f8df161c61b8dfa6f4bd5f4af677273f255f01ae84853a80fcde4c07f03e51dcad9dcf007afa5a1120521c641d35c23d07b1edfc51c90d7b8b216b179d27ea9
 DIST aircrack-ng-1.2-rc2.tar.gz 2046531 SHA256 ba5b3eda44254efc5b7c9f776eb756f7cc323ad5d0813c101e92edb483d157e9 SHA512 49794c80a76da20698d0372a81fdbd54f2defb694c23807369be7632e57d21cb09f14d3013b199f247663286c316714ee0fae8a6d302cabbe48ffa1e6ebefc56 WHIRLPOOL d0a221a840ab7541648b204bc8e38108fe125999167a8477cf5a1cfc309a892fd72c888bad28ab83fc049b46a5817b72e9da6d5e0c6ed9cea97ba4ea741765f3
+DIST aircrack-ng-1.2-rc3.tar.gz 4303552 SHA256 8e595ccab9fe90fc7c770634ad13e30da2d7fef21497b34d56d7014b991a4585 SHA512 31ebe38bf418431b2ed770a7c8286e4321d2d4b253b2b1e94450de012823d9530dfaa302ae0797dd1a31b93ff4b40e9577bdf9fe3b818650758b5eebc80d67dc WHIRLPOOL a14e21828fa279eecd80ae6ed7341bbda37e44d022f0eca45cd208690dff7fdbbe43b7188d56ccb9be39393d4b412ce0b9534bd662d7fa72f50c03024dd8bccb
diff --git a/net-wireless/aircrack-ng/aircrack-ng-1.2_rc3.ebuild b/net-wireless/aircrack-ng/aircrack-ng-1.2_rc3.ebuild
new file mode 100644
index 000000000000..cce7f35093cf
--- /dev/null
+++ b/net-wireless/aircrack-ng/aircrack-ng-1.2_rc3.ebuild
@@ -0,0 +1,144 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_OPTIONAL=1
+
+inherit toolchain-funcs distutils-r1 flag-o-matic
+
+DESCRIPTION="WLAN tools for breaking 802.11 WEP/WPA keys"
+HOMEPAGE="http://www.aircrack-ng.org"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit subversion
+	ESVN_REPO_URI="http://svn.aircrack-ng.org/trunk"
+	KEYWORDS=""
+	S="${WORKDIR}/${PN}"
+else
+	#inherit versionator
+	#MY_P=${P/\_/-}
+	#MY_PV="$(replace_version_separator 2 '-')"
+	#SRC_URI="http://download.aircrack-ng.org/${PN}-${MY_PV}.tar.gz"
+	#KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+	#S="${WORKDIR}/${MY_P}"
+	MY_PV=${PV/_/-}
+	SRC_URI="http://download.${PN}.org/${PN}-${MY_PV}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="+airdrop-ng +airgraph-ng kernel_linux kernel_FreeBSD +netlink +pcre +sqlite +experimental"
+
+DEPEND="net-libs/libpcap
+	dev-libs/openssl:0=
+	netlink? ( dev-libs/libnl:3 )
+	pcre? ( dev-libs/libpcre )
+	airdrop-ng? ( ${PYTHON_DEPS} )
+	airgraph-ng? ( ${PYTHON_DEPS} )
+	experimental? ( sys-libs/zlib )
+	sqlite? ( >=dev-db/sqlite-3.4 )"
+RDEPEND="${DEPEND}
+	kernel_linux? (
+		net-wireless/iw
+		net-wireless/wireless-tools
+		sys-apps/ethtool
+		sys-apps/usbutils
+		sys-apps/pciutils )
+	sys-apps/hwids
+	airdrop-ng? ( net-wireless/lorcon[python,${PYTHON_USEDEP}] )"
+
+REQUIRED_USE="airdrop-ng? ( ${PYTHON_REQUIRED_USE} )
+		airgraph-ng? ( ${PYTHON_REQUIRED_USE} )"
+
+src_compile() {
+	if [[ $($(tc-getCC) --version) == clang* ]] ; then
+		die "Please use gcc, upstream bug http://trac.aircrack-ng.org/ticket/1144"
+	fi
+
+	if [[ ${PV} == "9999" ]] ; then
+		liveflags=REVFLAGS=-D_REVISION="${ESVN_WC_REVISION}"
+	fi
+
+	emake \
+	CC="$(tc-getCC)" \
+	AR="$(tc-getAR)" \
+	LD="$(tc-getLD)" \
+	RANLIB="$(tc-getRANLIB)" \
+	libnl=$(usex netlink true false) \
+	pcre=$(usex pcre true false) \
+	sqlite=$(usex sqlite true false) \
+	experimental=$(usex experimental true false) \
+	${liveflags}
+
+	if use airgraph-ng; then
+		cd "${S}/scripts/airgraph-ng"
+		distutils-r1_src_compile
+	fi
+	if use airdrop-ng; then
+		cd "${S}/scripts/airdrop-ng"
+		distutils-r1_src_compile
+	fi
+}
+
+src_test() {
+	if [[ ${PV} == "9999" ]] ; then
+		liveflags=REVFLAGS=-D_REVISION="${ESVN_WC_REVISION}"
+	fi
+
+	emake check \
+		libnl=$(usex netlink true false) \
+		pcre=$(usex pcre true false) \
+		sqlite=$(usex sqlite true false) \
+		experimental=$(usex experimental true false) \
+		${liveflags}
+}
+
+src_install() {
+	if [[ ${PV} == "9999" ]] ; then
+		liveflags=REVFLAGS=-D_REVISION="${ESVN_WC_REVISION}"
+	fi
+
+	emake \
+		prefix="${ED}/usr" \
+		libnl=$(usex netlink true false) \
+		pcre=$(usex pcre true false) \
+		sqlite=$(usex sqlite true false) \
+		experimental=$(usex experimental true false) \
+		${liveflags} \
+		install
+
+	dodoc AUTHORS ChangeLog INSTALLING README
+
+	if use airgraph-ng; then
+		cd "${S}/scripts/airgraph-ng"
+		distutils-r1_src_install
+	fi
+	if use airdrop-ng; then
+		cd "${S}/scripts/airdrop-ng"
+		distutils-r1_src_install
+	fi
+
+	#we don't need aircrack-ng's oui updater, we have our own
+	rm "${ED}"/usr/sbin/airodump-ng-oui-update
+}
+
+pkg_postinst() {
+	# Message is (c) FreeBSD
+	# http://www.freebsd.org/cgi/cvsweb.cgi/ports/net-mgmt/aircrack-ng/files/pkg-message.in?rev=1.5
+	if use kernel_FreeBSD ; then
+		einfo "Contrary to Linux, it is not necessary to use airmon-ng to enable the monitor"
+		einfo "mode of your wireless card.  So do not care about what the manpages say about"
+		einfo "airmon-ng, airodump-ng sets monitor mode automatically."
+		echo
+		einfo "To return from monitor mode, issue the following command:"
+		einfo "    ifconfig \${INTERFACE} -mediaopt monitor"
+		einfo
+		einfo "For aireplay-ng you need FreeBSD >= 7.0."
+	fi
+}
diff --git a/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild b/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
index 134a722b851d..cce7f35093cf 100644
--- a/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
+++ b/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
@@ -26,7 +26,7 @@ else
 	#S="${WORKDIR}/${MY_P}"
 	MY_PV=${PV/_/-}
 	SRC_URI="http://download.${PN}.org/${PN}-${MY_PV}.tar.gz"
-	KEYWORDS="amd64 arm ppc x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+	KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
 	S="${WORKDIR}/${PN}-${MY_PV}"
 fi