sci-electronics/nvc: drop old 1.14.1

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

2 files changed, 0 insertions, 117 deletions

diff --git a/sci-electronics/nvc/Manifest b/sci-electronics/nvc/Manifest
index 9a1fe44512d6..7849350de7b0 100644
--- a/sci-electronics/nvc/Manifest
+++ b/sci-electronics/nvc/Manifest
@@ -1,3 +1,2 @@
-DIST nvc-1.14.1.tar.gz 2033076 BLAKE2B 8c17d08aaf01d8dec293530b9e28e37261396e846433a574532e7d1c68bd13424879e25a00e186e46523fa73b9e731a624088312c8133b3fa0d5626f42681d8b SHA512 13648a8c9b952a64c0ec053f733f359ee138a0a3f02ac160ed8d7ac2ace0db658a9092695229a0fe6d1bebf7bae4386969b6b2883e720ae6f4e8ab8098960cc2
 DIST nvc-1.14.2.tar.gz 2035337 BLAKE2B 999540938a31ea0d622eeaeca93a0910bcd7af1d36470b9ecbee37dfc53dba6c1a56d543665c7b8ada18a81d0755818d6b570d06610e139436a1c53d57d0241c SHA512 90b9be206628784f39eac721e92e70a5b9b2b6043973f51b18f45df8c50e642bddcc149c02a8bea6d433b91d5fac1678107581832ca24f433f63e1450162fb2d
 DIST nvc-1.15.0.tar.gz 2110906 BLAKE2B 0b451e35c535af09660567f176b217eeeeb17203ef9ab6f6f16796e981bf92da4b27c9251642bf5abd8ff63c292154013c739d3c7fa131368f4b5d865e234c9a SHA512 965bd7ff8bd1c59317f8d2c7c2e466f41e009765ea18dd09212c844a8142cd1aa5d5e20db4628285f3d3998345e2a0ccf2a89081fcdf3baa6abe777163c46ac5
diff --git a/sci-electronics/nvc/nvc-1.14.1.ebuild b/sci-electronics/nvc/nvc-1.14.1.ebuild
deleted file mode 100644
index 8dbe5b2eb22f..000000000000
--- a/sci-electronics/nvc/nvc-1.14.1.ebuild
+++ /dev/null
@@ -1,116 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LLVM_COMPAT=( {17..18} )
-
-inherit autotools bash-completion-r1 llvm-r1
-
-DESCRIPTION="NVC is a VHDL compiler and simulator"
-HOMEPAGE="https://www.nickg.me.uk/nvc/
-	https://github.com/nickg/nvc/"
-
-if [[ "${PV}" == *9999* ]] ; then
-	inherit git-r3
-
-	EGIT_REPO_URI="https://github.com/nickg/nvc.git"
-
-	NVC_SOURCEDIR="${WORKDIR}/${PN}-${PV}"
-else
-	SRC_URI="https://github.com/nickg/nvc/archive/r${PV}.tar.gz
-		-> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~x86"
-
-	NVC_SOURCEDIR="${WORKDIR}/${PN}-r${PV}"
-fi
-
-NVC_BUILDDIR="${NVC_SOURCEDIR}_BuildDir"
-S="${NVC_BUILDDIR}"
-
-LICENSE="GPL-3+"
-SLOT="0"
-IUSE="debug llvm"
-RESTRICT="test"         # Some tests fail.
-
-RDEPEND="
-	app-arch/bzip2:=
-	app-arch/zstd:=
-	dev-libs/capstone:=
-	dev-libs/elfutils
-	dev-libs/icu:=
-	dev-libs/libffi:=
-	dev-libs/libxml2:=
-	sys-libs/ncurses:=
-	sys-libs/zlib:=
-	llvm? (
-		$(llvm_gen_dep '
-			llvm-core/llvm:${LLVM_SLOT}=
-		')
-	)
-"
-DEPEND="
-	${RDEPEND}
-"
-BDEPEND="
-	dev-libs/check
-	sys-apps/which
-	sys-devel/bison
-	sys-devel/flex
-"
-
-PATCHES=( "${FILESDIR}/nvc-1.9.2-jit-code-capstone.patch" )
-
-# Special libraries for NVC.
-QA_FLAGS_IGNORED="usr/lib[0-9]*/nvc/preload[0-9]*.so"
-
-pkg_setup() {
-	use llvm && llvm-r1_pkg_setup
-}
-
-src_unpack() {
-	default
-
-	mkdir -p "${S}" || die
-}
-
-src_prepare() {
-	pushd "${NVC_SOURCEDIR}" >/dev/null || die
-
-	default
-	eautoreconf
-
-	popd >/dev/null || die
-}
-
-src_configure() {
-	# Needs "bison" and "flex" exactly.
-	unset LEX
-	unset YACC
-
-	local ECONF_SOURCE="${NVC_SOURCEDIR}"
-	local -a myconf=(
-		--enable-vital
-		--with-bash-completion="$(get_bashcompdir)"
-		$(use_enable debug)
-		$(use_enable llvm)
-	)
-	econf "${myconf[@]}"
-
-	export V=1          # Verbose compilation and install.
-}
-
-src_compile() {
-	emake -j1
-}
-
-src_test() {
-	PATH="${S}/bin:${PATH}" emake check-TESTS
-}
-
-src_install() {
-	default
-
-	mv "${D}/$(get_bashcompdir)"/nvc{.bash,} || die
-	dostrip -x "/usr/$(get_libdir)/nvc"
-}