sci-libs/rtabmap: Bump to 0.10.5 and update live ebuild.

Package-Manager: portage-2.2.20.1

3 files changed, 73 insertions, 6 deletions

diff --git a/sci-libs/rtabmap/Manifest b/sci-libs/rtabmap/Manifest
index 7ce03fd0147a..62bd318fc18b 100644
--- a/sci-libs/rtabmap/Manifest
+++ b/sci-libs/rtabmap/Manifest
@@ -1,3 +1,4 @@
+DIST rtabmap-0.10.5.tar.gz 16975400 SHA256 2c783d7a3c872b084bde18466863fda6d8c8247ff279dbee40f1d3da69b1667a SHA512 a144387d6cbe4ad9b656216c269505768a60408ae9486b41d85c8ed0f8a1212b8f598d392c147d042f8b3ade57974b2b8ae6e5ec8c47e6a18f11d53ce8a086e9 WHIRLPOOL 76faf97da79a5c7693b6ca41422c92d5bb47b6c1cc6ccec6658df2721ad1219ba41be3a6c15bf3c9f9d7c7b9e384141d04c1c996fe604edab2b3e03506c7f8c5
 DIST rtabmap-0.8.2.tar.gz 16314234 SHA256 058006a00e550187ca382308985723573735e64bc7bb833357a47929949ef6b0 SHA512 fc2f3152c9651fc847881d773b788d0845a0c842ee3dd8508f395de0954072a0aeb0d37bf55389e29bcc4d14027845218dbda7ef346f2161669be6570eb785f5 WHIRLPOOL 5ac7b2b30742ff360d7755c016735f59542fe828c80689686a449f3ab4d2e40ad568ae9a0ad8d148cfd221e43da463e0409238b5a94ce600970a9d0162f97368
 DIST rtabmap-0.8.3.tar.gz 16331307 SHA256 cc19a57fc50f5bccd25dda2383993f04164074348f6a75b1f83b8ae152b88ff8 SHA512 a326d3704bc4f1eeb1cc102919192b2999c49b1a5460ccb9c39721829a80e7889a4549b203f5aafeacdbe482e114de275508e3b22cb0a466cfa831e736766a30 WHIRLPOOL 7a338f58c0731b3ae9e2793432a720099cd84634b2115fa8d97b31066afa2fc8ec348a6c9e25fba691f6051d52ab1af62dddbac00dffc27c99a9658b52154011
 DIST rtabmap-0.9.0.tar.gz 16871134 SHA256 d64afbf4075e249665a0d19259f40c587c8cebb11b70d60ad8c48b6822066ba1 SHA512 86002dbdbca917901b0a17c1eca948d012c5bd4b29bf334b093478b740a07b3bce6699340df41f64e477be19dad3be757bca6dba962939fba1ecb3c8462f9891 WHIRLPOOL 06d1201a4d7339df4941b45ce6785781659da96e8b2ab9f281bd13a23fa4f68b0f5e70b23e6479300cc128044e44159f8b9c73ac14cd631c704e9a66ad496a1e
diff --git a/sci-libs/rtabmap/rtabmap-0.10.5.ebuild b/sci-libs/rtabmap/rtabmap-0.10.5.ebuild
new file mode 100644
index 000000000000..8fdd4089e4cf
--- /dev/null
+++ b/sci-libs/rtabmap/rtabmap-0.10.5.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM="git-r3"
+	EGIT_REPO_URI="https://github.com/introlab/rtabmap"
+fi
+
+inherit ${SCM} cmake-utils multilib
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+	KEYWORDS=""
+	SRC_URI=""
+else
+	KEYWORDS="~amd64"
+	SRC_URI="https://github.com/introlab/rtabmap/archive/${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+DESCRIPTION="Real-Time Appearance-Based Mapping (RGB-D Graph SLAM)"
+HOMEPAGE="http://introlab.github.io/rtabmap/"
+LICENSE="BSD"
+SLOT="0"
+IUSE="ieee1394 openni2 qt4 qt5"
+
+RDEPEND="
+	media-libs/opencv:=
+	sci-libs/pcl[openni,vtk]
+	sci-libs/vtk
+	sys-libs/zlib
+	ieee1394? ( media-libs/libdc1394 )
+	openni2? ( dev-libs/OpenNI2 )
+	!qt5? (
+		qt4? (
+			dev-qt/qtgui:4
+			dev-qt/qtsvg:4
+			dev-qt/qtcore:4
+			media-libs/opencv[-qt5(-)]
+		)
+	)
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtsvg:5
+		media-libs/opencv[qt5(-)]
+	)
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_configure() {
+	local mycmakeargs=(
+		"-DWITH_QT=$(usex qt4 ON "$(usex qt5 ON OFF)")"
+		"-DRTABMAP_QT_VERSION=$(usex qt5 5 4)"
+		"-DWITH_DC1394=$(usex ieee1394 ON OFF)"
+		"-DWITH_OPENNI2=$(usex openni2 ON OFF)"
+	)
+	cmake-utils_src_configure
+}
diff --git a/sci-libs/rtabmap/rtabmap-9999.ebuild b/sci-libs/rtabmap/rtabmap-9999.ebuild
index c3183be626f3..8fdd4089e4cf 100644
--- a/sci-libs/rtabmap/rtabmap-9999.ebuild
+++ b/sci-libs/rtabmap/rtabmap-9999.ebuild
@@ -28,7 +28,7 @@ IUSE="ieee1394 openni2 qt4 qt5"
 
 RDEPEND="
 	media-libs/opencv:=
-	sci-libs/pcl[openni]
+	sci-libs/pcl[openni,vtk]
 	sci-libs/vtk
 	sys-libs/zlib
 	ieee1394? ( media-libs/libdc1394 )
@@ -38,6 +38,7 @@ RDEPEND="
 			dev-qt/qtgui:4
 			dev-qt/qtsvg:4
 			dev-qt/qtcore:4
+			media-libs/opencv[-qt5(-)]
 		)
 	)
 	qt5? (
@@ -45,16 +46,18 @@ RDEPEND="
 		dev-qt/qtcore:5
 		dev-qt/qtgui:5
 		dev-qt/qtsvg:5
+		media-libs/opencv[qt5(-)]
 	)
 "
 DEPEND="${RDEPEND}
 	virtual/pkgconfig"
 
 src_configure() {
-	local mycmakeargs=()
-	use ieee1394 || mycmakeargs+=( "-DCMAKE_DISABLE_FIND_PACKAGE_DC1394=TRUE" )
-	use openni2  || mycmakeargs+=( "-DCMAKE_DISABLE_FIND_PACKAGE_OpenNI2=TRUE" )
-	use qt4      || mycmakeargs+=( "-DCMAKE_DISABLE_FIND_PACKAGE_Qt4=TRUE" )
-	use qt5      && mycmakeargs+=( "-DRTABMAP_QT_VERSION=5" )
+	local mycmakeargs=(
+		"-DWITH_QT=$(usex qt4 ON "$(usex qt5 ON OFF)")"
+		"-DRTABMAP_QT_VERSION=$(usex qt5 5 4)"
+		"-DWITH_DC1394=$(usex ieee1394 ON OFF)"
+		"-DWITH_OPENNI2=$(usex openni2 ON OFF)"
+	)
 	cmake-utils_src_configure
 }