sci-visualization/gr: add 0.73.6

Closes: https://bugs.gentoo.org/930586
Signed-off-by: Andreas K. Hüttel <dilfridge@gentoo.org>

2 files changed, 86 insertions, 0 deletions

diff --git a/sci-visualization/gr/Manifest b/sci-visualization/gr/Manifest
index 83af848e109d..b0e363ea593b 100644
--- a/sci-visualization/gr/Manifest
+++ b/sci-visualization/gr/Manifest
@@ -1,2 +1,3 @@
 DIST gr-0.72.4.tar.gz 9067899 BLAKE2B 827c80dbfc3483abe4af217c06549c64aa134446e831a5d7fab3906a3aac7bb23b66f8b98674220ff1b6fbd5fad60b9a8e7f7361a27370c033d9375a18f63234 SHA512 4ae1aae6854995ae58327d41930cedd96ef973ce65467f48f24d9985b27b5af2aa0eb6832a801b46e6fa71cade99117957c96738cb000306b0574b0e471692fb
 DIST gr-0.73.3.tar.gz 10076655 BLAKE2B 13bd461b39a86473290912f5a9ba5a4b5ea3ffc8865f6909aad1fc92acf6d39fdb12910e2bf0f8108b7bef1016652515c6cc188db0b98dd052459400b30895ba SHA512 f45daefd880eec9380a2a31f1cd3b124469c1d33c34a9d13a3718b1978da507620b6f7cc025dd20be81a70f52537dbb4537548d8cc32e133693d9b7ae2f476e5
+DIST gr-0.73.6.tar.gz 10109682 BLAKE2B 15499dc9dbe42b3530edcba29a1ca82f05051a499a0656af1fa94a90d6b9ac3a321118694c80f2e52b092a8b3840105d92cf6df1fe079062183ea11de995c20b SHA512 4b96b55c540ec2984042ff308c7ef73cfed1008c4de8a4b77be3e13db06cfeb648e5e0ec511a2387b4c545005aa7924d40b74c0d8a62f30d2c36388e3f2b9128
diff --git a/sci-visualization/gr/gr-0.73.6.ebuild b/sci-visualization/gr/gr-0.73.6.ebuild
new file mode 100644
index 000000000000..8e55d4f9c9ba
--- /dev/null
+++ b/sci-visualization/gr/gr-0.73.6.ebuild
@@ -0,0 +1,85 @@
+# Copyright 2019-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Universal framework for cross-platform visualization applications"
+HOMEPAGE="https://gr-framework.org/"
+SRC_URI="https://github.com/sciapp/gr/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="agg cairo ffmpeg postscript tiff truetype"
+
+DEPEND="
+	dev-qt/qtgui:=
+	media-libs/fontconfig
+	media-libs/glfw
+	media-libs/libjpeg-turbo:=
+	media-libs/libpng:=
+	media-libs/qhull:=
+	net-libs/zeromq
+	sys-libs/zlib
+	virtual/opengl
+	x11-libs/libX11
+	x11-libs/libXt
+	agg? ( x11-libs/agg )
+	cairo? ( x11-libs/cairo )
+	ffmpeg? ( media-video/ffmpeg:= )
+	postscript? ( app-text/ghostscript-gpl )
+	tiff? ( media-libs/tiff:= )
+	truetype? ( media-libs/freetype )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.53.0-musl.patch"
+)
+
+REQUIRED_USE="cairo? ( truetype )"
+
+src_configure() {
+	if use agg ; then
+		mycmakeargs+=( -DAGG_LIBRARY=/usr/$(get_libdir)/libagg.so -DAGG_INCLUDE_DIR=/usr/include/agg2 )
+	else
+		mycmakeargs+=( -DAGG_LIBRARY= )
+	fi
+
+	use cairo || mycmakeargs+=( -DCAIRO_LIBRARY= )
+	use postscript || mycmakeargs+=( -DGS_LIBRARY= )
+	use ffmpeg || mycmakeargs+=( -DFFMPEG_INCLUDE_DIR= )
+	use truetype || mycmakeargs+=( -DFREETYPE_LIBRARY= )
+	use tiff || mycmakeargs+=( -DTIFF_LIBRARY= )
+
+	# todo: X11 automagic
+
+	mycmakeargs+=( -DCMAKE_INSTALL_PREFIX=/usr/gr )
+	mycmakeargs+=( -DCMAKE_INSTALL_LIBDIR=lib )
+	#
+	# I need to have a serious conversation with upstream.
+	# * The main consumer of this package is dev-lang/julia.
+	# * If I patch gr to install in standard locations, julia does
+	#   not find it anymore.
+	# * I can't patch julia, since the corresponding scripts are
+	#   downloaded at runtime from its package registry ...
+	# * See bug 882619 in addition.
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	find "${ED}" -name '*.a' -delete
+
+	echo "GRDIR=/usr/gr" > "${T}/99gr"
+	echo "LDPATH=/usr/gr/$(get_libdir)" >> "${T}/99gr"
+	doenvd "${T}/99gr"
+
+	[[ -f "${ED}/usr/gr/bin/gksqt" ]] && dosym ../gr/bin/gksqt /usr/bin/gksqt
+
+	elog "${P} relies on the environment variable GRDIR. If you want to use it in a running shell,"
+	elog "e.g. with dev-lang/julia, then run \"source /etc/profile\" first."
+}