sci-visualization/gr: Version bump. Now useful for Julia.

Bug: https://bugs.gentoo.org/725862
Closes: https://bugs.gentoo.org/683188
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Andreas K. Huettel <dilfridge@gentoo.org>

2 files changed, 71 insertions, 0 deletions

diff --git a/sci-visualization/gr/Manifest b/sci-visualization/gr/Manifest
index ad263e8f1937..8682c7cdbaf8 100644
--- a/sci-visualization/gr/Manifest
+++ b/sci-visualization/gr/Manifest
@@ -1 +1,2 @@
 DIST gr-0.49.0.tar.gz 8604669 BLAKE2B a4f14910b8b229e722018a00e7f7f1b0c354265282b16c49e536bb8771a1bd69c0e0c17a9e4e70593f185e6c58885fcb6842b2f2c121988c1c161f5d11548b1b SHA512 851deac9cc2f42a9f62883e6bfb4bcc6e71e46910ec97a7b5fec087299f12d09043365f594d47c315a23079342bf25893b1a0f59bbd0e92eb140cc2a11126a14
+DIST gr-0.50.0.tar.gz 8612608 BLAKE2B 70f4a3c6ce1dac8556646a1632667e6e464a5048f3c44fb689709e3e8218e8d7375db6ff8ce73e11dbeda559fb27c83b7f2b42f0ab518df9b464c8443748c30e SHA512 34ca077ae729e6eda0e5df7046811c77d717f3ef0e34203d6ab3a7f4b67b3aa058a68b9b2d7d78adc8b2f0830a0298778198a6499bd3d6e5697e4b7270cb648a
diff --git a/sci-visualization/gr/gr-0.50.0.ebuild b/sci-visualization/gr/gr-0.50.0.ebuild
new file mode 100644
index 000000000000..71d7cb7c9312
--- /dev/null
+++ b/sci-visualization/gr/gr-0.50.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 2019-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Universal framework for cross-platform visualization applications"
+HOMEPAGE="http://gr-framework.org/"
+SRC_URI="https://github.com/sciapp/gr/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cairo ffmpeg opengl postscript qt5 tiff truetype X"
+
+DEPEND="
+	media-libs/fontconfig
+	media-libs/libjpeg-turbo
+	media-libs/libpng
+	media-libs/qhull
+	sys-libs/zlib
+	cairo? ( x11-libs/cairo )
+	ffmpeg? ( media-video/ffmpeg )
+	opengl? (
+		media-libs/glfw
+		virtual/opengl
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	qt5? ( dev-qt/qtgui:5 )
+	tiff? ( media-libs/tiff )
+	truetype? ( media-libs/freetype )
+	X? ( x11-libs/libX11 )
+"
+RDEPEND="${DEPEND}"
+BDEPEND=""
+
+src_configure() {
+	use cairo || mycmakeargs+=( -DCAIRO_LIBRARY= )
+	use opengl || mycmakeargs+=( -DGLFW_LIBRARY= )
+	use postscript || mycmakeargs+=( -DGS_LIBRARY= )
+	use ffmpeg || mycmakeargs+=( -DFFMPEG_INCLUDE_DIR= )
+	use truetype || mycmakeargs+=( -DFREETYPE_LIBRARY= )
+	use tiff || mycmakeargs+=( -DTIFF_LIBRARY= )
+
+	# todo: Qt5, X11 automagic
+
+	mycmakeargs+=( -DCMAKE_INSTALL_PREFIX=/usr/gr )
+	#
+	# I need to have a serious conversation with upstream.
+	# * The main consumer of this package is dev-lang/julia.
+	# * If I patch gr to install in standard locations, julia does
+	#   not find it anymore.
+	# * I can't patch julia, since the corresponding scripts are
+	#   downloaded at runtime from its package registry ...
+	#
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	find "${ED}" -name '*.a' -delete
+
+	echo "GRDIR=/usr/gr" > "${T}/99gr"
+	echo "LDPATH=/usr/gr/$(get_libdir)" >> "${T}/99gr"
+	doenvd "${T}/99gr"
+
+	dosym ../gr/bin/gksqt /usr/bin/gksqt
+}