sys-devel/llvm-toolchain-symlinks: Remove LLVM 14

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 0 insertions, 47 deletions

diff --git a/sys-devel/llvm-toolchain-symlinks/llvm-toolchain-symlinks-14-r1.ebuild b/sys-devel/llvm-toolchain-symlinks/llvm-toolchain-symlinks-14-r1.ebuild
deleted file mode 100644
index 444095748cf9..000000000000
--- a/sys-devel/llvm-toolchain-symlinks/llvm-toolchain-symlinks-14-r1.ebuild
+++ /dev/null
@@ -1,47 +0,0 @@
-# Copyright 2022-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit multilib
-
-DESCRIPTION="Symlinks to use LLVM on binutils-free system"
-HOMEPAGE="https://wiki.gentoo.org/wiki/Project:LLVM"
-S=${WORKDIR}
-
-LICENSE="public-domain"
-SLOT="${PV}"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~ppc-macos ~x64-macos"
-IUSE="multilib-symlinks +native-symlinks"
-
-RDEPEND="
-	sys-devel/llvm:${SLOT}
-"
-
-src_install() {
-	use native-symlinks || return
-
-	local tools=(
-		addr2line ar dlltool nm objcopy objdump ranlib readelf size
-		strings strip windres
-	)
-	local chosts=( "${CHOST}" )
-	if use multilib-symlinks; then
-		local abi
-		for abi in $(get_all_abis); do
-			chosts+=( "$(get_abi_CHOST "${abi}")" )
-		done
-	fi
-
-	local chost t
-	local dest=/usr/lib/llvm/${SLOT}/bin
-	dodir "${dest}"
-	for t in "${tools[@]}"; do
-		dosym "llvm-${t}" "${dest}/${t}"
-	done
-	for chost in "${chosts[@]}"; do
-		for t in "${tools[@]}"; do
-			dosym "llvm-${t}" "${dest}/${chost}-${t}"
-		done
-	done
-}