sys-fs/duperemove: Bump to v0.10

Update to v0.10. Major changes include:

- support for offloading memory and storing hashes on disk
  during deduplication (requires sqlite3);
- libgcrypt hashing has been replaced by three bundled hashes
  to choose from: murmur3, sha256 and xxhash;
- support for reusing fdupes output;
- multi-threading support.

Package-Manager: portage-2.2.23

1 files changed, 34 insertions, 0 deletions

diff --git a/sys-fs/duperemove/duperemove-0.10.ebuild b/sys-fs/duperemove/duperemove-0.10.ebuild
new file mode 100644
index 000000000000..a39e6e67c033
--- /dev/null
+++ b/sys-fs/duperemove/duperemove-0.10.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="Btrfs deduplication utility"
+HOMEPAGE="https://github.com/markfasheh/duperemove"
+SRC_URI="https://github.com/markfasheh/duperemove/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+# includes code from libbloom, xxhash (BSD-2)
+# includes code from polarssl (GPL-2+)
+LICENSE="GPL-2 GPL-2+ BSD-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+RDEPEND="
+	dev-db/sqlite:3=
+	dev-libs/glib:2="
+DEPEND="${RDEPEND}"
+
+src_compile() {
+	# CC & CFLAGS are set via = so need to override them
+	# LIBRARY_FLAGS are set via += so need to pass them via env
+	local -x LIBRARY_FLAGS="${LDFLAGS}"
+	emake CC="$(tc-getCC)" CFLAGS="${CFLAGS} -Wall"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="/usr" install
+}