www-client/opera-beta: bump to 79.0.4143.15

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Stephan Hartmann <sultan@gentoo.org>

2 files changed, 158 insertions, 0 deletions

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index e15123021934..f2c4c1746514 100644
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1,5 +1,6 @@
 DIST opera-beta_78.0.4093.103_amd64.deb 77211528 BLAKE2B 0df5d6c7bdaee9147a3cc621aa549c24a4f7c128a0017fbb7b6e2350ace0ffcdc267810334aaf901f4f50f2ce7526a5ca2b32110b69f170ac67f24989ca162ac SHA512 5dc7ef7ac24c6a7ef78b79862d3f39f4d1d99f4b351e7a7a118e3c82028421f1bf23d9c9dbb3e6ef7018cc8eb2ddc95c96290fe01e3505fd5970214431a26fd5
 DIST opera-beta_78.0.4093.79_amd64.deb 77241316 BLAKE2B 3d678a96ccc40df1047380ca7c15b018663407406d267d30eb0dfd328a7eb1b28d78734b45034ff2ebb4ab73bb6d38adc24be031f6e451ad2f97f5d97c4090a1 SHA512 d1abb8bf7494ac36d8268f3c2c3862b3337948bc68b4a5c65bb070f5aa391e2c45d0c328ba572b745d68dc54b306a9c913eb0fffa0bce557e1f3b9ec7cff09fb
+DIST opera-beta_79.0.4143.15_amd64.deb 77600048 BLAKE2B 8f1e1889a3f38d70b77ed3f27d61e987d1cabd36cdfa2dae87febe946a70bb17e11a1b63c1d1cbafcfb3e16b69ecc7cafcb16879fe1ae7c6e311af425e96456a SHA512 4b7330ae98e1445041370736f88eb468daaf9a4c6d244004cdb5e335dd0f970344015f1f379e3a40fb62dbda606b2722e4f2f7d6b1c2651ad2c49db11697f5bd
 DIST opera-beta_79.0.4143.3_amd64.rpm 75224832 BLAKE2B 7275033acb4e6ea07438ca8a0fb028ad57146e252a3b70488c8682a34c109c8dcdbab61e0d9e2efa176b3ed87249273d87d24c52ac89cc2f7c9ac0f246b815ca SHA512 01832a2bbb7ff48ff0be65d1dd20aa747ad7289feb06b111da32843b4b76d419f7da5dab6a25bb64f75ee2c57e67fc766c666eb6b351e3f4b299e6ce1e27630f
 DIST opera-ffmpeg-codecs-92.0.4515.20.tar.xz 1382256 BLAKE2B 1e00bb4ee655573ac7b6c2f04ae2ae9a073f839ff6deeba3e3c4c2c58a10b1152068f0549fb3c6de758628317ad7c568cf5d3031294208800b470e3ed00c938b SHA512 6aeec66a9fcea1fcf5ecfd23b56589598f5e612e788b4e417037250470b83f91e461e3b0c20caf7853677d314053ca9d489983736708f15d21a82d68d2cdd5c2
 DIST opera-ffmpeg-codecs-93.0.4573.0.tar.xz 1389664 BLAKE2B 4efc7341655bed294d4c6237dd9e7d005a815c495a45bec6f0b7fcbec40345e22ad5199ec1db3c822c123663d3ce95e6b87af18b1ac6cad31793ae7fdb440918 SHA512 f7c62c6860d1440e91344c41d6c9b3fbef4745cb95262538dcb3af9147406b3b0c71e72605042c423cbdd618a53f902791bcb6b7fcc8a4cae92ebf3cb38e8407
diff --git a/www-client/opera-beta/opera-beta-79.0.4143.15.ebuild b/www-client/opera-beta/opera-beta-79.0.4143.15.ebuild
new file mode 100644
index 000000000000..d85e8c828656
--- /dev/null
+++ b/www-client/opera-beta/opera-beta-79.0.4143.15.ebuild
@@ -0,0 +1,157 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	OPERA_UNPACKER="rpm"
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	OPERA_UNPACKER="unpacker"
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+inherit chromium-2 multilib pax-utils ${OPERA_UNPACKER} xdg
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="93.0.4573.0"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+	proprietary-codecs? (
+		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}