www-plugins/lightspark: version bump to 0.8.0

Bug: https://bugs.gentoo.org/show_bug.cgi?id=625228

Package-Manager: Portage-2.3.6, Repoman-2.3.1

3 files changed, 103 insertions, 2 deletions

diff --git a/www-plugins/lightspark/Manifest b/www-plugins/lightspark/Manifest
index 1a0910293645..7fa387c7c0f9 100644
--- a/www-plugins/lightspark/Manifest
+++ b/www-plugins/lightspark/Manifest
@@ -1 +1,2 @@
 DIST lightspark-0.7.2_p20160107.tar.gz 1803064 SHA256 83b58db86e466e9a3acc33c7c1bbff284edb3f7fef377a3397ac26ac06cac22f SHA512 937352c8d428579a9ac89a45724db2beb624eba874da59d684e07d9d306305d85937f4b2e692c56750a1b5e6ca485e05d9997409d3bc934fab209124cd471601 WHIRLPOOL 268f2a95758def3fb722daa6580e6c4ff5577eacdc27e82005ce7e0b51d55ae78fbc6ae5c1d839b4b21848a0d2a61b0b023f4741487fc042450a7a20bfee01bb
+DIST lightspark-0.8.0.tar.gz 1830071 SHA256 b0612a93bb16c0ab9ea5d516ee312607e14703d26ca917d037bb33e235ed4b25 SHA512 333de501caf5f5ed9c8581cfda5bf1e6e04170c90f1c2f6150c9c2343f9de20e140a041d066f693e406d24fa24e7a5c3464675a583f4a5c104f5214ebee072b9 WHIRLPOOL 4ba1e18a9196823603146ce178914c5778a6eac045b994afbbe388cb945612bb5bab8072a77bfe0b647aeff614f3f4d8b34161c118fe9102745f2ba26c102e00
diff --git a/www-plugins/lightspark/lightspark-0.8.0.ebuild b/www-plugins/lightspark/lightspark-0.8.0.ebuild
new file mode 100644
index 000000000000..d67d565b6b3c
--- /dev/null
+++ b/www-plugins/lightspark/lightspark-0.8.0.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils nsplugins vcs-snapshot toolchain-funcs
+
+DESCRIPTION="High performance flash player"
+HOMEPAGE="http://lightspark.github.io/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cpu_flags_x86_sse2 curl ffmpeg gles libav nsplugin ppapi profile rtmp"
+
+# Note: code-wise llvm-4.0 is fine but due to CMake bug it can't work:
+# https://gitlab.kitware.com/cmake/cmake/issues/16606
+RDEPEND="app-arch/xz-utils:0=
+	dev-cpp/glibmm:2=
+	>=dev-libs/boost-1.42:0=
+	dev-libs/glib:2=
+	dev-libs/libpcre:3=[cxx]
+	media-fonts/liberation-fonts
+	media-libs/freetype:2=
+	media-libs/libpng:0=
+	media-libs/libsdl2:0=
+	media-libs/sdl2-mixer:0=
+	>=sys-devel/gcc-4.6.0:*[cxx]
+	>=sys-devel/llvm-3.4:0=
+	sys-libs/zlib:0=
+	x11-libs/cairo:0=
+	x11-libs/gtk+:2=
+	x11-libs/libX11:0=
+	x11-libs/pango:0=
+	virtual/jpeg:0=
+	curl? ( net-misc/curl:0= )
+	ffmpeg? (
+		libav? ( media-video/libav:0= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	gles? ( media-libs/mesa:0=[gles2] )
+	!gles? (
+		>=media-libs/glew-1.5.3:0=
+		virtual/opengl:0=
+	)
+	rtmp? ( media-video/rtmpdump:0= )"
+DEPEND="${RDEPEND}
+	amd64? ( dev-lang/nasm )
+	x86? ( dev-lang/nasm )
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${P/_rc*/}
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]]; then
+		if tc-is-gcc && [[ $(gcc-major-version) == 4 && $(gcc-minor-version) -lt 6 || $(gcc-major-version) -lt 4 ]] ; then
+			eerror "You need at least sys-devel/gcc-4.6.0"
+			die "You need at least sys-devel/gcc-4.6.0"
+		fi
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_CURL=$(usex curl)
+		-DENABLE_GLES2=$(usex gles)
+		-DENABLE_LIBAVCODEC=$(usex ffmpeg)
+		-DENABLE_RTMP=$(usex rtmp)
+
+		-DENABLE_MEMORY_USAGE_PROFILING=$(usex profile)
+		-DENABLE_PROFILING=$(usex profile)
+		-DENABLE_SSE2=$(usex cpu_flags_x86_sse2)
+
+		-DCOMPILE_NPAPI_PLUGIN=$(usex nsplugin)
+		-DPLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/${PN}/plugins
+		# TODO: install /etc/chromium file? block adobe-flash?
+		-DCOMPILE_PPAPI_PLUGIN=$(usex ppapi)
+		-DPPAPI_PLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/chromium-browser/${PN}
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use nsplugin && inst_plugin /usr/$(get_libdir)/${PN}/plugins/liblightsparkplugin.so
+}
+
+pkg_postinst() {
+	if use nsplugin && ! has_version www-plugins/gnash; then
+		elog "Lightspark now supports gnash fallback for its browser plugin."
+		elog "Install www-plugins/gnash to take advantage of it."
+	fi
+	if use nsplugin && has_version "www-plugins/gnash[nsplugin]"; then
+		elog "Having two plugins installed for the same MIME type may confuse"
+		elog "Mozilla based browsers. It is recommended to disable the nsplugin"
+		elog "USE flag for either gnash or lightspark. For details, see"
+		elog "https://bugzilla.mozilla.org/show_bug.cgi?id=581848"
+	fi
+}
diff --git a/www-plugins/lightspark/lightspark-9999.ebuild b/www-plugins/lightspark/lightspark-9999.ebuild
index d0de6eda5899..435e878ed31e 100644
--- a/www-plugins/lightspark/lightspark-9999.ebuild
+++ b/www-plugins/lightspark/lightspark-9999.ebuild
@@ -27,7 +27,6 @@ RDEPEND="app-arch/xz-utils:0=
 	media-libs/libsdl2:0=
 	media-libs/sdl2-mixer:0=
 	>=sys-devel/gcc-4.6.0:*[cxx]
-	<sys-devel/llvm-4:0=
 	>=sys-devel/llvm-3.4:0=
 	sys-libs/zlib:0=
 	x11-libs/cairo:0=
@@ -73,7 +72,7 @@ src_configure() {
 		-DENABLE_PROFILING=$(usex profile)
 		-DENABLE_SSE2=$(usex cpu_flags_x86_sse2)
 
-		-DCOMPILE_PLUGIN=$(usex nsplugin)
+		-DCOMPILE_NPAPI_PLUGIN=$(usex nsplugin)
 		-DPLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/${PN}/plugins
 		# TODO: install /etc/chromium file? block adobe-flash?
 		-DCOMPILE_PPAPI_PLUGIN=$(usex ppapi)