xfce-base/xfce4-power-manager: Bump to 4.17.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 76 insertions, 0 deletions

diff --git a/xfce-base/xfce4-power-manager/Manifest b/xfce-base/xfce4-power-manager/Manifest
index 200412ded410..4e59a79ea4fd 100644
--- a/xfce-base/xfce4-power-manager/Manifest
+++ b/xfce-base/xfce4-power-manager/Manifest
@@ -1 +1,2 @@
 DIST xfce4-power-manager-4.16.0.tar.bz2 1234968 BLAKE2B 0299bc293769411384b34c81c907f75ba6503db11f1636366a599938d37eda0843e1850c584c37186529c0c97eaca73bc5d488d4916087a42c5c5f68ae8787c8 SHA512 1c6ecfb7696bc13c9b11fdfb4ad4e3278de2350bbc59c84c933b28c07c1a0c55b9954794e1f57e4407d2b54ffaace9ea5baed829bf0683332cf9d12bff7e71ec
+DIST xfce4-power-manager-4.17.0.tar.bz2 1239130 BLAKE2B 10eb3b877c83f909d39d1bbbb447e7c954f195c83c73a1430890db391edef3a5abc021f0e9130b15269b980dd988fe9faed074f55a38ca4ff514bed411d1c001 SHA512 d2bda60f98db131e7ce7b057f253f3c72068d36d31a9fd83ea28663b119431762909d519b5f8218ab43f110b7bf89a4e02adab09eeafe12c8c4a7bc540c4dcbf
diff --git a/xfce-base/xfce4-power-manager/xfce4-power-manager-4.17.0.ebuild b/xfce-base/xfce4-power-manager/xfce4-power-manager-4.17.0.ebuild
new file mode 100644
index 000000000000..5bedd2bb3ea2
--- /dev/null
+++ b/xfce-base/xfce4-power-manager/xfce4-power-manager-4.17.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="Power manager for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfce4-power-manager/start
+	https://gitlab.xfce.org/xfce/xfce4-power-manager/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="networkmanager +panel-plugin policykit"
+
+DEPEND="
+	>=dev-libs/glib-2.50
+	>=sys-power/upower-0.99.0
+	>=x11-libs/gtk+-3.14:3
+	>=x11-libs/libnotify-0.7
+	x11-libs/libX11
+	>=x11-libs/libXrandr-1.2
+	x11-libs/libXext
+	x11-libs/libXtst
+	>=xfce-base/xfconf-4.12:=
+	>=xfce-base/libxfce4ui-4.12:=[gtk3(+)]
+	>=xfce-base/libxfce4util-4.12:=
+	panel-plugin? ( >=xfce-base/xfce4-panel-4.12:= )
+	policykit? ( >=sys-auth/polkit-0.112 )
+"
+RDEPEND="
+	${DEPEND}
+	networkmanager? ( net-misc/networkmanager )
+"
+DEPEND+="
+	x11-base/xorg-proto
+"
+BDEPEND="
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable policykit polkit)
+		$(use_enable networkmanager network-manager)
+		$(use_enable panel-plugin xfce4panel)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	if ! has_version sys-apps/systemd && ! has_version sys-auth/elogind
+	then
+		elog "Suspend/hibernate support requires a logind provider installed"
+		elog "(sys-apps/systemd or sys-auth/elogind)"
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}