1 files changed, 39 insertions, 0 deletions
diff --git a/app-laptop/tpb/tpb-0.6.4-r1.ebuild b/app-laptop/tpb/tpb-0.6.4-r1.ebuild
new file mode 100644
index 000000000000..f9c57af8d3a3
--- /dev/null
+++ b/app-laptop/tpb/tpb-0.6.4-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit linux-info eutils
+
+DESCRIPTION="IBM ThinkPad buttons utility"
+HOMEPAGE="http://savannah.nongnu.org/projects/tpb/"
+SRC_URI="http://savannah.nongnu.org/download/tpb/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 -ppc x86"
+IUSE="nls xosd"
+
+RDEPEND="x11-libs/libXt
+	x11-libs/libXext
+	xosd? ( >=x11-libs/xosd-2.2.0 )"
+DEPEND="${RDEPEND}"
+
+CONFIG_CHECK="~NVRAM"
+ERROR_NVRAM="${P} requires /dev/nvram support (CONFIG_NVRAM)"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-configure-fix.diff
+	epatch "${FILESDIR}"/${P}-nvram.patch
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		$(use_enable xosd)
+}
+
+src_install() {
+	default
+	dodoc doc/{callback_example.sh,nvram.txt,tpbrc}
+}