1 files changed, 45 insertions, 0 deletions
diff --git a/dev-libs/libuv/libuv-1.5.0.ebuild b/dev-libs/libuv/libuv-1.5.0.ebuild
new file mode 100644
index 000000000000..f1f71e4527eb
--- /dev/null
+++ b/dev-libs/libuv/libuv-1.5.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit autotools-utils eutils multilib multilib-minimal
+
+DESCRIPTION="Cross-platform asychronous I/O"
+HOMEPAGE="https://github.com/libuv/libuv"
+SRC_URI="https://github.com/libuv/libuv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD BSD-2 ISC MIT"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="static-libs"
+
+DEPEND="sys-devel/libtool
+	virtual/pkgconfig[${MULTILIB_USEDEP}]"
+
+src_prepare() {
+	echo "m4_define([UV_EXTRA_AUTOMAKE_FLAGS], [serial-tests])" \
+		> m4/libuv-extra-automake-flags.m4 || die
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		cc_cv_cflags__g=no
+		$(use_enable static-libs static)
+	)
+	autotools-utils_src_configure
+}
+
+multilib_src_test() {
+	mkdir "${BUILD_DIR}"/test || die
+	cp -pPR "${S}"/test/fixtures "${BUILD_DIR}"/test/fixtures || die
+	default
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}