1 files changed, 48 insertions, 0 deletions
diff --git a/dev-libs/qtkeychain/qtkeychain-0.12.0.ebuild b/dev-libs/qtkeychain/qtkeychain-0.12.0.ebuild
new file mode 100644
index 000000000000..b2a7c0bb00b7
--- /dev/null
+++ b/dev-libs/qtkeychain/qtkeychain-0.12.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+HOMEPAGE="https://github.com/frankosterfeld/qtkeychain"
+DESCRIPTION="Qt API for storing passwords securely"
+
+if [[ ${PV} != *9999* ]]; then
+	SRC_URI="https://github.com/frankosterfeld/qtkeychain/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+else
+	inherit git-r3
+	EGIT_REPO_URI="${HOMEPAGE}.git"
+fi
+
+LICENSE="BSD-2"
+SLOT="0/1"
+IUSE="gnome-keyring"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+"
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	gnome-keyring? (
+		app-crypt/libsecret
+		dev-libs/glib:2
+	)
+"
+RDEPEND="${DEPEND}"
+
+DOCS=( ChangeLog ReadMe.md )
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_WITH_QT6=OFF
+		-DQTKEYCHAIN_STATIC=OFF
+		-DBUILD_TEST_APPLICATION=OFF
+		-DBUILD_TRANSLATIONS=ON
+		-DLIBSECRET_SUPPORT=$(usex gnome-keyring)
+	)
+
+	cmake_src_configure
+}