1 files changed, 58 insertions, 0 deletions
diff --git a/dev-python/jaraco-stream/jaraco-stream-1.2-r1.ebuild b/dev-python/jaraco-stream/jaraco-stream-1.2-r1.ebuild
new file mode 100644
index 000000000000..6e61e406dd65
--- /dev/null
+++ b/dev-python/jaraco-stream/jaraco-stream-1.2-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7}} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Routines for handling streaming data"
+HOMEPAGE="https://github.com/jaraco/jaraco.stream"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc test"
+
+RDEPEND="
+	<dev-python/namespace-jaraco-2[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.9[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+		dev-python/more-itertools[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+		>=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Skip one test which requires network access
+	# Override pytest options to skip flake8
+	PYTHONPATH=. pytest -vv --ignore=jaraco/stream/test_gzip.py \
+		--override-ini="addopts=--doctest-modules" \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${ED}" -name '*.pth' -delete || die
+}