1 files changed, 58 insertions, 0 deletions
diff --git a/dev-python/scikit-image/scikit-image-0.13.0-r1.ebuild b/dev-python/scikit-image/scikit-image-0.13.0-r1.ebuild
new file mode 100644
index 000000000000..6764d75ad7cf
--- /dev/null
+++ b/dev-python/scikit-image/scikit-image-0.13.0-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit distutils-r1 optfeature virtualx
+
+MYPN="${PN/scikits_/scikit-}"
+MYP="${MYPN}-${PV}"
+
+DESCRIPTION="Image processing routines for SciPy"
+HOMEPAGE="https://scikit-image.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${MYPN}/${MYP}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc freeimage pyamg test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pywavelets[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/scipy[sparse,${PYTHON_USEDEP}]
+	freeimage? ( media-libs/freeimage )
+	pyamg? ( dev-python/pyamg[${PYTHON_USEDEP}] )"
+DEPEND="${RDEPEND}
+	>=dev-python/cython-0.23[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (	dev-python/nose[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MYP}"
+
+DOCS=( CONTRIBUTORS.txt DEPENDS.txt RELEASE.txt TASKS.txt TODO.txt )
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}" || die "no ${TEST_DIR} available"
+	echo "backend : Agg" > matplotlibrc || die
+	#echo "backend.qt4 : PyQt4" >> matplotlibrc || die
+	#echo "backend.qt4 : PySide" >> matplotlibrc || die
+	MPLCONFIGDIR=. virtx nosetests --exe -v skimage
+}
+
+pkg_postinst() {
+	optfeature "FITS io capability" dev-python/astropy
+	optfeature "GTK" dev-python/pygtk
+	optfeature "Parallel computation" dev-python/dask
+	# not in portage yet
+	#optfeature "io plugin providing a wide variety of formats, including specialized formats using in medical imaging." dev-python/simpleitk
+	#optfeature "io plugin providing most standard formats" dev-python/imread
+}