1 files changed, 44 insertions, 0 deletions
diff --git a/gnome-extra/polkit-gnome/polkit-gnome-0.105-r2.ebuild b/gnome-extra/polkit-gnome/polkit-gnome-0.105-r2.ebuild
new file mode 100644
index 000000000000..b271426d6e23
--- /dev/null
+++ b/gnome-extra/polkit-gnome/polkit-gnome-0.105-r2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome.org
+
+DESCRIPTION="A dbus session bus service that is used to bring up authentication dialogs"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/polkit"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE=""
+
+DEPEND=">=dev-libs/glib-2.30
+	>=sys-auth/polkit-0.102
+	x11-libs/gtk+:3"
+RDEPEND="${DEPEND}
+	!lxde-base/lxpolkit"
+BDEPEND="dev-util/intltool
+	virtual/pkgconfig
+	sys-devel/gettext"
+
+DOCS=( AUTHORS HACKING NEWS README TODO )
+
+src_install() {
+	default
+
+	cat <<-EOF > "${T}"/polkit-gnome-authentication-agent-1.desktop
+	[Desktop Entry]
+	Name=PolicyKit Authentication Agent
+	Comment=PolicyKit Authentication Agent
+	Exec=/usr/libexec/polkit-gnome-authentication-agent-1
+	Terminal=false
+	Type=Application
+	Categories=
+	NoDisplay=true
+	NotShowIn=MATE;KDE;
+	AutostartCondition=GNOME3 if-session gnome-fallback
+	EOF
+
+	insinto /etc/xdg/autostart
+	doins "${T}"/polkit-gnome-authentication-agent-1.desktop
+}