1 files changed, 44 insertions, 0 deletions
diff --git a/media-libs/faac/faac-1.28-r3.ebuild b/media-libs/faac/faac-1.28-r3.ebuild
new file mode 100644
index 000000000000..50f879c47bb7
--- /dev/null
+++ b/media-libs/faac/faac-1.28-r3.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit autotools eutils
+
+DESCRIPTION="Free MPEG-4 audio codecs by AudioCoding.com"
+HOMEPAGE="http://www.audiocoding.com"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1 MPEG-4"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="static-libs"
+
+RDEPEND="media-libs/libmp4v2:0="
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${P}-external-libmp4v2.patch \
+		"${FILESDIR}"/${P}-altivec.patch \
+		"${FILESDIR}"/${P}-libmp4v2_r479_compat.patch \
+		"${FILESDIR}"/${P}-inttypes.patch
+
+	sed -i -e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' configure.in || die #466984
+
+	eautoreconf
+	epunt_cxx
+}
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog NEWS README TODO
+	dohtml docs/*.html
+	insinto /usr/share/doc/${PF}/pdf
+	doins docs/libfaac.pdf
+	prune_libtool_files
+}