1 files changed, 58 insertions, 0 deletions
diff --git a/media-libs/freeverb3/freeverb3-2.6.6.ebuild b/media-libs/freeverb3/freeverb3-2.6.6.ebuild
new file mode 100644
index 000000000000..1b2f2c45a452
--- /dev/null
+++ b/media-libs/freeverb3/freeverb3-2.6.6.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=2
+inherit multilib versionator
+
+DESCRIPTION="High Quality Reverb and Impulse Response Convolution library including XMMS/Audacious Effect plugins"
+HOMEPAGE="http://freeverb3.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="audacious cpu_flags_x86_avx jack plugdouble cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_sse4_1 cpu_flags_x86_3dnow forcefpu"
+
+RDEPEND=">=sci-libs/fftw-3.0.1
+	audacious? ( <media-sound/audacious-3
+		media-libs/libsndfile )
+	jack? ( media-sound/jack-audio-connection-kit
+		media-libs/libsndfile )"
+DEPEND=${RDEPEND}
+
+S="${WORKDIR}/${PN}-$(get_version_component_range 1-3)"
+
+src_configure() {
+	# TODO: Expose --enable-pthread (of >=2.6.0) to the outside
+	econf \
+		--enable-release \
+		--disable-bmp \
+		--disable-pluginit \
+		$(use_enable audacious) \
+		$(use_enable jack) \
+		$(use_enable plugdouble) \
+		--disable-autocflags \
+		$(use_enable cpu_flags_x86_3dnow 3dnow) \
+		$(use_enable cpu_flags_x86_sse sse) \
+		$(use_enable cpu_flags_x86_sse2 sse2) \
+		$(use_enable cpu_flags_x86_sse3 sse3) \
+		$(use_enable cpu_flags_x86_sse4_1 sse4) \
+		$(use_enable cpu_flags_x86_avx avx) \
+		--disable-fma \
+		--disable-fma4 \
+		$(use_enable forcefpu) \
+		|| die "econf failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc ChangeLog README || die 'dodoc failed'
+
+	if use audacious ; then
+		find "${D}/usr/$(get_libdir)/audacious/" -name '*.la' -print -delete || die
+	fi
+
+	insinto /usr/share/${PN}/samples/IR
+	doins samples/IR/*.wav || die
+}