1 files changed, 45 insertions, 0 deletions
diff --git a/media-libs/libao/libao-1.1.0-r1.ebuild b/media-libs/libao/libao-1.1.0-r1.ebuild
new file mode 100644
index 000000000000..2375cacf67e0
--- /dev/null
+++ b/media-libs/libao/libao-1.1.0-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+
+inherit libtool multilib eutils
+
+DESCRIPTION="The Audio Output library"
+HOMEPAGE="http://www.xiph.org/ao/"
+SRC_URI="http://downloads.xiph.org/releases/ao/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 sh sparc x86 ~x86-fbsd ~x86-interix ~amd64-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+IUSE="alsa nas mmap pulseaudio static-libs"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	nas? ( media-libs/nas )
+	pulseaudio? ( media-sound/pulseaudio )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	sed -i -e 's:-O20::' configure || die
+	sed -i -e "s:/lib:/$(get_libdir):g" ao.m4 || die
+	elibtoolize
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		--disable-esd \
+		$(use_enable alsa alsa) \
+		$(use_enable mmap alsa-mmap) \
+		--disable-arts \
+		$(use_enable nas) \
+		$(use_enable pulseaudio pulse)
+}
+
+src_install() {
+	emake DESTDIR="${D}" docdir="${EPREFIX}/usr/share/doc/${PF}/html" install
+	dodoc AUTHORS CHANGES README TODO
+	prune_libtool_files --all
+}