1 files changed, 45 insertions, 0 deletions
diff --git a/net-misc/cadaver/cadaver-0.23.3.ebuild b/net-misc/cadaver/cadaver-0.23.3.ebuild
new file mode 100644
index 000000000000..def16c40a2b4
--- /dev/null
+++ b/net-misc/cadaver/cadaver-0.23.3.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="3"
+
+inherit autotools eutils
+
+DESCRIPTION="Command-line WebDAV client"
+HOMEPAGE="http://www.webdav.org/cadaver"
+SRC_URI="http://www.webdav.org/cadaver/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ppc64 ~sparc x86"
+IUSE="nls"
+
+RDEPEND=">=net-libs/neon-0.27.0"
+DEPEND="${RDEPEND}
+	sys-devel/gettext"
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-0.23.2-disable-nls.patch"
+
+	rm -fr lib/{expat,intl,neon}
+	sed \
+		-e "/NE_REQUIRE_VERSIONS/s/29/& 30/" \
+		-e "s:lib/neon/Makefile lib/intl/Makefile ::" \
+		-i configure.ac || die "sed configure.ac failed"
+	sed -e "s/^\(SUBDIRS.*=\).*/\1/" -i Makefile.in || die "sed Makefile.in failed"
+	cp /usr/share/gettext/po/Makefile.in.in po || die "cp failed"
+
+	AT_M4DIR="m4 m4/neon" eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		--with-libs=/usr
+}
+
+src_install () {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc BUGS ChangeLog FAQ NEWS README THANKS TODO
+}