blob: d60fccdd5d6a9290713fb4815d6ea9b623b20953 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit gnome.org meson multilib-minimal systemd virtualx xdg
DESCRIPTION="D-Bus accessibility specifications and registration daemon"
HOMEPAGE="https://wiki.gnome.org/Accessibility"
LICENSE="LGPL-2.1+"
SLOT="2"
IUSE="X gtk-doc +introspection"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 s390 ~sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
RDEPEND="
>=sys-apps/dbus-1.5[${MULTILIB_USEDEP}]
>=dev-libs/glib-2.36:2[${MULTILIB_USEDEP}]
introspection? ( >=dev-libs/gobject-introspection-1.54.0:= )
X? (
x11-libs/libX11[${MULTILIB_USEDEP}]
x11-libs/libXtst[${MULTILIB_USEDEP}]
x11-libs/libXi[${MULTILIB_USEDEP}]
)
"
DEPEND="${RDEPEND}"
BDEPEND="
>=dev-util/meson-0.50.0
dev-util/glib-utils
gtk-doc? (
>=dev-util/gtk-doc-1.25
app-text/docbook-xml-dtd:4.3 )
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
"
PATCHES=(
# disable teamspaces test since that requires Novell.ICEDesktop.Daemon
"${FILESDIR}/${PN}-2.0.2-disable-teamspaces-test.patch"
)
multilib_src_configure() {
local emesonargs=(
-Dsystemd_user_dir="$(systemd_get_userunitdir)"
-Ddocs=$(multilib_native_usex gtk-doc true false)
-Dintrospection=$(multilib_native_usex introspection)
-Dx11=$(usex X)
)
meson_src_configure
}
multilib_src_compile() {
meson_src_compile
}
multilib_src_test() {
virtx meson_src_test
}
multilib_src_install() {
meson_src_install
}
|
GitWeb
